Eigene ACE Action auf Türen

iV Ghost · 16. September 2020

Ich versuche mich mal wieder seit Stunden daran, eine eigene ACE Action auf Türen zu geben - leider vergebens.

Code

private _halfMap = worldSize / 2;
private _radius = worldSize / 1.5;
private _allBuildings = nearestObjects [[_halfMap, _halfMap], ["house"], _radius];
{
// GET NUMBER OF DOORS FROM A BUILDING
private _className = configFile >> "CfgVehicles" >> typeOf _x;
private _num = getNumber (_className >> "numberofdoors");
private _pos = getPos _x;
// GET NAMES FROM THE DOORS
private _building = _x;
private _selectionNames = selectionNames _building;
private _allDoors = _selectionNames select {toUpper _x find "DOOR" >= 0 && toUpper _x find "HANDLE" == -1};
// HANDLE EACH DOOR
{
// ACE3 ACTION
private _selectionPos = _building selectionPosition _x;
private _selectionName = _x;
private _statement = {
params ["_target", "_caller", "_args"];
_args params ["_selectionName", "_selectionPos"];
hint format ["_target = %1 \n\n _selectionName = %2 \n\n _selectionPos = %3", _target, _selectionName, _selectionPos];
};
// CREATE ACE ACTION
private _action = ["iV_DoorActions", "Breaching", "", _statement, {true}, {}, [_selectionName, _selectionPos], _selectionName] call ace_interact_menu_fnc_createAction;
[_building, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToObject;
} forEach _allDoors;
} forEach _allBuildings;

Alles anzeigen

Die ACE Action ist nicht auf der Tür, sondern auf dem Gebäude.

Hat vlt einer einen Tipp für mich?

Christovur · 17. September 2020

Also ich hab das mal aus einem anderen Skript geklaut, um ein Lockpicking zu erlauben. Vielleicht hilft dir das ja:

Code

[
milshed,
"Türschloss knacken",
"\a3\ui_f\data\IGUI\Cfg\holdactions\holdAction_connect_ca.paa",
"\a3\ui_f\data\IGUI\Cfg\holdactions\holdAction_connect_ca.paa",
"
call {
private ['_intersects','_select_door'];
_intersects = ([cursorObject, 'VIEW'] intersect [ASLToATL eyepos player, (screentoworld [0.5,0.5])]);
_select_door = if (count _intersects > 0 && {(_intersects select 0) select 0 in ['door_5','door_3','door_1']}) then [{format ['bis_disabled_%1', (_intersects select 0 select 0)]},{''}];
if (_this distance _target < 10 && _select_door in ['bis_disabled_door_5','bis_disabled_door_1','bis_disabled_door_3']) then {
MGI_select_door = _select_door; true
} else {false};
};
true",
"true", {}, {},
{
if (_target getVariable [MGI_select_door,1] !=0) then {
_target setVariable[MGI_select_door,0,true]
} else {
_target setVariable[MGI_select_door,1,true]
}
}, {}, [], 10, nil, false, false, false
] remoteExec ["BIS_fnc_holdActionAdd", 0, true];

Alles anzeigen

iV Ghost · 17. September 2020

Nein, leider nicht. Trotzdem danke.

Ich habe es bisher auf eine addAction - funktioniert problemlos.

Nur da ich mehrere Breaching Möglichkeiten auf eine Tür legen möchte,

fänd ich es am schönsten mit einer ACE Action umgesetzt.

Ich verstehe leider nicht, warum er den SelectionName nicht erkennt.

Auch mit SelectionPosition probiert. Soll doch gehen.

iV Ghost · 18. September 2020

Selbst wenn ich im Editor ein Gebäude (Industrieschuppen, Varname = MyHouse) platziere und dann folgendes in der Console aufrufe funktioniert es nicht:

Code

private _action = ["iV_DoorActions", "Breaching", "", {hint "DONE!"}, {true}, {}, [], {MyHouse selectionPosition "door_3"}] call ace_interact_menu_fnc_createAction;
[MyHouse, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToObject;

Zumi · 25. September 2020

Ich habe das probiert und es über die Selections auch nicht hingekriegt. Mir ist aber für meine Mission ein Workaround gelungen.

Demo hier:

Sieht jetzt etwas einfacher aus, als es ist. Es benötigt einige Custom CBA Events, publicVariables und so weiter.

Zumi · 25. September 2020

Das Türe knacken habe ich so gelöst:

Ich mache das mit den Ace Interaktionen etwas speziell. Es ist nicht über die Config, sondern über Scripts gelöst.

Zumi · 25. September 2020

Ace scheint für die Interaktions-Knoten auf den Häusern Helferobjekte zu verwenden. Daher habe ich mich entschieden, es über eine Selbst-Interaktion zu lösen.

ACE3/fnc_userActions_addHouseActions.sqf at master · acemod/ACE3 · GitHub

commy2 · 25. September 2020

Die Frage wurde schon hier beantwortet:

Create ACE3 action on doors · Issue #7911 · acemod/ACE3 · GitHub

Zumi · 25. September 2020

Zitat von commy2

Die Frage wurde schon hier beantwortet:
Create ACE3 action on doors · Issue #7911 · acemod/ACE3 · GitHub

Sehr gut. Wie vermutet.

Zumi · 25. September 2020

Der Code (Ace-Event, welches gehandelt wird):

Code

["ace_explosives_detonate", {
params ["_unit", "_explosive", "_delay"];
private _array = _explosive call CBA_fnc_getNearestBuilding;
_array params ["_building", "_buildingPositions"];
_bounding_rotated = [(boundingCenter _building), vectorUp _building, -(getDir _building)] call CBA_fnc_vectRotate3D;
_hpos = (_building call cba_fnc_getPos) vectorAdd _bounding_rotated;
_bpos = (getPosATL _explosive);
for "_i" from 1 to 20 do {
private _offset = _building selectionPosition format ["door_%1", _i];
if !(_offset isEqualTo [0,0,0]) then {
private _offset = [_offset, vectorUp _building, -(getDir _building)] call CBA_fnc_vectRotate3D;
private _newpos = _hpos vectorAdd _offset;
if (_bpos distance _newpos <= 2) then {
_building setVariable [format ["bis_disabled_door_%1", _i], 0, true];
private _return = [_building, format ["door_%1", _i]] call ace_interaction_fnc_getDoorAnimations;
_return params [["_animations", []], ["_lockedVariable", []]];
if !(_animations isEqualTo []) then {
_building animate [_animations select 0, 1];
};
};
};
};
}] call CBA_fnc_addEventHandler;

Alles anzeigen

Edit: der funktionierende Code

.

Zumi · 28. September 2020

Got it

Teilen