Waffenanbauteile automatisch zum begrenzten Virtuell Arsenal hinzufügen?

Drunken Officer · 26. Mai 2023

Hallo in die Runde.

Ich habe vor in meiner nächsten Mission die Truppe mit einem begrenzten Arsenal ausrüsten zu lassen.

Dafür habe ich die Waffen als Array angelegt. Das Auslesen der Magazine funktioniert, jedoch ermittelt mein Script nicht automatisch die Anbauteile. Ich habe es jetzt händisch eingetragen, würde es aber gern automatisch ablaufen lassen.

Kann mir da einer helfen?

Hier mein Sctipt

Code

_weapon_base = [
"BWA3_G27", "BWA3_G27_AG40", "BWA3_G27_tan","BWA3_G27_AG40_tan",
"BWA3_G38", "BWA3_G38_tan", "BWA3_G38_AG40", "BWA3_G38_Ag40_tan",
"BWA3_G38C", "BWA3_G38C_tan", "BWA3_G38k", "BWA3_G38_tan", "BWA3_G38k_Ag40", "BWA3_G38_AG40_tan",
"BWA3_G36A1", "BWA3_G36A1_green", "BWA3_G36A1_tan", "BWA3_G36A1_AG40", "BWA3_G36A1_AG40_green", "BWA3_G36A1_AG40_tan",
"BWA3_G36A2", "BWA3_G36A2_green", "BWA3_G36A2_tan", "BWA3_G36A2_AG40", "BWA3_G36A2_AG40_green", "BWA3_G36A2_AG40_tan",
"BWA3_G36A3", "BWA3_G36A3_green", "BWA3_G36A3_tan", "BWA3_G36A3_AG40", "BWA3_G36A3_AG40_green", "BWA3_G36A3_AG40_tan",
"BWA3_G36KA0", "BWA3_G36KA0_green", "BWA3_G36KA0_tan",
"BWA3_G36KA1", "BWA3_G36KA1_green", "BWA3_G36KA1_tan",
"BWA3_G36KA2", "BWA3_G36KA2_green", "BWA3_G36KA2_tan",
"BWA3_G36KA3", "BWA3_G36KA3_green", "BWA3_G36KA3_tan",
"BWA3_G36KA4", "BWA3_G36KA4_green", "BWA3_G36KA4_tan",
"BWA3_MP7",
"BWA3_RGW90_Loaded","BWA3_PzF3_Tandem_Loaded", "BWA3_Bunkerfaust_Loaded", "BWA3_Fliegerfaust",
"BWA3_P12"
];
_magazine =[];
_optics =[];
_laser =[];
_muzzle = [];
{
_collectedmags = (getArray (configFile >> "cfgWeapons" >> _x >> "Magazines")); {_magazine pushBack _x } foreach _collectedmags;
_collectedOptics = (getArray (configFile >> "cfgWeapons" >> _x >> "WeaponSlotsInfo" >> "CowsSlot" >> "compatibleItems")); {_optics pushBack _x } foreach _collectedOptic;
_collectedLaser = (getArray (configFile >> "cfgWeapons" >> _x >> "WeaponSlotsInfo" >> "PointerSlot" >> "compatibleItems")); {_laser pushBack _x } foreach _collectedLaser;
_collectedMuzzle = (getArray (configFile >> "cfgWeapons" >>_x >> "WeaponSlotsInfo" >> "MuzzleSlot" >> "compatibleItems")); {_muzzle pushBack _x } foreach _collectedMuzzle;
} forEach _weapon_base;

Alles anzeigen

Pyro · 1. Juni 2023

Zitat von BI Wiki

Bexternal classes CowsSlot and PointerSlot are used for standard optics and side accessory. That means these classes are outside cfgWeapons and changeable for all weapons at once.

Heißt du wirst da so über die CfgWeapons nichts finden.
Mit compatibleItems und compatibleMagazines sollte es funktionieren. Habe es für Dich mal umgeschrieben. (btw. hast du _collectedOptics einmal als _collectedOptic ohne s angesprochen.)

Viel Erfolg mit deiner Mission!

SQL

_weapon_base = [
"arifle_katiba_f"
];
_magazine =[];
_optics =[];
_laser =[];
_muzzle = [];
{
_collectedmags = compatibleMagazines _x; {_magazine pushBack _x } foreach _collectedmags;
_collectedOptic = compatibleItems [_x, "CowsSlot"]; {_optics pushBack _x } foreach _collectedOptic;
_collectedLaser = compatibleItems [_x, "PointerSlot"]; {_laser pushBack _x } foreach _collectedLaser;
_collectedMuzzle = compatibleItems [_x, "MuzzleSlot"]; {_muzzle pushBack _x } foreach _collectedMuzzle;
} forEach _weapon_base;

Alles anzeigen

Waffenanbauteile automatisch zum begrenzten Virtuell Arsenal hinzufügen?

Teilen

Tags