Briefing Template

    • Tut- Complete

    Diese Seite verwendet Cookies. Durch die Nutzung unserer Seite erklären Sie sich damit einverstanden, dass wir Cookies setzen. Weitere Informationen

    • Briefing Template

      Ein schönes Briefing macht eine Mission erst rund.

      Oft wird jedoch aus Faulheit oder Unkenntnis darauf verzichtet.

      Wenn ein Briefing vorhanden ist, so werden meist die im Eden Editor vorhandenen Module verwendet. Ok, reicht meistens.

      Jeder der aber seine Mission nach 3 Wochen wieder bearbeiten will und das Chaos an Briefing Modulen sieht, muss sich erst wieder durch die Tasks durchkämpfen um die Spielfolge nachzuvollziehen.
      Dabei ist ein schönes Briefing mit ein paar Extras ziemlich einfach zu gestalten:

      Ich verwende dazu nie die Eden Module, da sie das Editing sehr unübersichtlich machen.
      Hier sei nun ein Weg über die Briefing.sqf dargestellt.

      ___________1. Erstellen einer Briefing.sqf____________________________________________________________
      - In Windows unter Windows Zubehör den Editor aufrufen
      - Datei speichern unter: Dateiname: Briefing.sqf
      ACHTUNG: Dateinamen müssen unter Windows sichtbar sein. Oft wird eine Briefing.sqf.txt erstellt. Datei muss Briefing.sqf benannt sein!
      Das Briefing kann über die Init.sqf oder einfach über einen Triggereintrag aufgerufen werden.

      Quellcode

      1. execVM "Briefing.sqf";

      ___________2. Um nun beliebige Briefing Rubriken aufzumachen wird ein "Diary" Eintrag erstellt:____________

      Quellcode

      1. _diary = player createDiaryRecord ["Diary", ["Credits", " bla bla "]];

      Die Rubrik "Credits" kann zB. in "Situation" oder "Mission" oder "Friendly Forces" umbenannt werden.
      In " bla bla " kommt der eigentlich Text rein.
      Es lassen sich somit beliebig viele Unterrubriken eröffnen: Wetter, Feindkräfte etc...

      ___________3. Textgestaltung:______________________________________________________________________
      Dazu können Marker (Auf der Karte wird die Position angezeigt), farbliche Verweise (rote Schrift, oder blauer Markerverweis) oder Bilder im Briefing eingebaut werden.

      a) Marker:
      Marker lassen sich im Briefing mit

      Quellcode

      1. <marker name=""MARKERNAME"">MARKERTEXT</marker>
      einbinden. Dazu im Editor den Marker setzen, ihn benennen zB: respawn_west und im Briefing wie folgt angeben.

      Quellcode

      1. <marker name=""respawn_west"">Start</marker>

      b) Textgestaltung:
      - Ein <br/> bedeutet eine Zeilenumbruch. Zwei <br/> <br/> bedeutet somit eine Leerzeile.

      c) Farbgestaltung:
      - Um eine Text farblich hervorzuheben kann die Farbe frei im HEX Spektrum bestimmt werden: Das #fc3200' bestimmt den Farbton: siehe Hex Farben Code
      - Die Schrift wird hier mit "PuristaMedium" in der Grösse "14" definiert.

      Quellcode

      1. <font face='PuristaMedium' size=14 color='#fc3200'> Text </font>


      d) Text und Farbgestaltung mit Markerverweis:
      Um nun einen Markerverweis im Briefing farblich hervorzuheben (ich nutze gerne rot für feindliche Stellungen) lassen sich der beschriebene Markerverweis mit der Farbdarstellung kombinieren:

      Quellcode

      1. <font face='PuristaMedium' size=14 color='#ff0000'><marker name=""Task1Marker"">Roadblock</marker></font>
      Und schon haben wir ein einen Verweis auf den "Task1Marker" der im Briefingtext mit "Roadblock" erscheint und rot hervorgehoben ist.

      c) Bild einfügen:
      Das Bild muss in dem Missionsordner hinterlegt sein. Es kann im .jpg oder .paa Format vorliegen.
      Hierbei ist auf die Größe (Höhe und Breite) sowie auf die Dateigröße (MB) zu achten. Bitte mehr als 200kb muss echt nicht sein.
      Die Mission wird dadurch nur unnötig aufgeblasen!

      Quellcode

      1. <img image='pictures\Bild1.jpg' width='250' height='250'/>
      Hier wird im Missionsunterordner "pictures" auf das Bild "Bild1.jpg" verwiesen, welchen die Höhe und Breite von 250 * 250 Pixel hat.

      ___________4. Tasks:______________________________________________________________________
      Die Tasks können ebenfalls mit den bereits vorgestellten Textbausteinen aufgehübscht werden. Blaue Schrift, Markerverweis etc...
      Relativ neu (mit der Mission EndGame) wurde von BI das Task Overhaul eingeführt. Hierbei können die verschiedenen Task mit einem Icon (siehe link) versehen werden.
      Damit dieses Feature funktioniert bedarf es einer Class Definition in der description.ext. Diese kann wie oben erwähnt über den Windows eigenen
      Texteditor erstellt werden. Für das TaskOverhaul Feature bitte:

      Quellcode

      1. class CfgTaskEnhancements
      2. {
      3. enable = 1; //0: disable new task features (default), 1: enable new task features & add new task markers and task widgets into the map
      4. 3d = 0; //0: do not use new 3D markers (default), 1: replace task waypoints with new 3D markers
      5. 3dDrawDist = 600; //3d marker draw distance (default: 2000)
      6. share = 1; //0: do not count assigned players (default), 1: count how many players have the task assigned
      7. propagate = 1; //0: do not propagate (default), 1: propagate shared tasks to subordinates
      8. };
      in die description.ext einfügen.

      Hier nun ein Template für ein Task:

      Quellcode

      1. task1 = player createSimpleTask ["Check IED"];
      2. task1 setSimpleTaskDescription ["Check a reported <font face='PuristaMedium' size=14 color='#fc3200'><marker name='Task1Marker'>IED location</marker></font>.", "Check IED", "Move"];
      3. task1 setSimpleTaskDestination markerpos "Task1Marker";
      4. task1 setSimpleTaskType "destroy";
      5. player setCurrentTask task1;
      In der 1. Zeile wird ein Task erstellt (Check IED)
      In der 2. Zeile wird der Text erstellt und ein Marker (Task1Marker) mit dem Text (IED location) versehen. Dieser ist rot (#fc3200).
      In der 3. Zeile wird im Spiel auf den Marker "Task1Marker" verwiesen und auf Kartenposition gezoomt.
      In der 4. Zeile ist das Icon des TaskOverhault definiert.

      In der 7. Zeile wird das Task für den Spieler automatisch aktiviert.

      So, das ist eigentlich auch schon alles. Mit ein paar wenigen Schritten lassen sich recht schön gestaltete Briefings erstellen. Folgend noch ein Template, Viel Spass:

      Quellcode

      1. _diary = player createDiaryRecord ["Diary", ["Credits", "
      2. mission by: me
      3. <br/>
      4. <br/>
      5. <font face='PuristaMedium' size=14 color='#fc3200'>
      6. Scripts:
      7. <br/>
      8. - Mein super Script
      9. <br/>
      10. </font>
      11. <br/>
      12. <br/>
      13. v01: 05.04.2017
      14. "]];
      15. player createDiaryRecord ["Diary",["Friendly Forces","
      16. <font face='PuristaMedium' size=14 color='#effc00'><marker name=""respawn_west"">Mission Command</marker></font>: 2 Units
      17. <br/>
      18. <font face='PuristaMedium' size=14 color='#0000fc'><marker name=""respawn_west"">Team Alpha</marker></font>: 6 Units
      19. <br/>
      20. <font face='PuristaMedium' size=14 color='#0cfc00'><marker name=""respawn_west"">Team Bravo</marker></font>: 6 Units
      21. <br/>
      22. <br/>
      23. Our contact Codename -Mohammed-
      24. <br/>
      25. <img image='pictures\Task4.jpg' width='250' height='250'/>
      26. "]];
      27. player createDiaryRecord ["Diary",["Situation","
      28. Bla bla
      29. <br/>
      30. <br/>
      31. Mehr Bla bla...
      32. "]];
      33. player createDiaryRecord ["Diary",["Mission","
      34. Sie sind <font face='PuristaMedium' size=14 color='#0cfc00'><marker name=""respawn_west"">hier</marker></font>.
      35. <br/>
      36. Gehen sie <marker name=""Task1Marker"">dorthin</marker>.
      37. <br/>
      38. <br/>
      39. Viel Spass
      40. "]];
      41. // tasks ===========================================================================
      42. task1 = player createSimpleTask ["Check IED"];
      43. task1 setSimpleTaskDescription ["Check a possible <font face='PuristaMedium' size=14 color='#fc3200'><marker name='Task1Marker'>IED location</marker></font>.", "Check IED", "Move"];
      44. task1 setSimpleTaskDestination markerpos "Task1Marker";
      45. task1 setSimpleTaskType "destroy";
      46. //Choose first mission task ===========================================================================
      47. player setCurrentTask task1;
      Alles anzeigen