große Fläche von Gras befreien

Maaxxs · 7. Mai 2016

Ich möchte zum Beispiel, dass in der Base kein Gras ist, also alles gemäht ist. Außerhalb soll das TerrainGrid so sein wie es eingestellt ist
Da die Base aber ziemlich groß ist, will ich keine 100e Cutter setzen.

Hat der wer Ideen? Wäre über alles dankbar

SawtoothDentist · 7. Mai 2016

Versuch doch mal eine Funktion zu bauen die einfach im Gebiet die Cutter zu Missionsbeginn erstellt und dann wieder löscht.
Keine Ahnung ob, aber könnte so funktionieren.

**Raven** · 7. Mai 2016

Du könntest mithilfe von nearestObjects alle Objekte innerhalb der Base finden und dann den entsprechenden Array durchgehen und falls es keines der eigentlichen Base Bestandteile ist dann kannst du hideGlobal benutzen ums verschwinden zu lassen...
Dann wären auch Steine und Sträucher aus der Gegend weg...

Das würde dann halt am besten funktionieren wenn die Base halbwegs rund ist da nearestObjects ja mit einem Radius arbeitet...

Creedcoder · 7. Mai 2016

Einfach eins der Objekte spawnen und gut ist, zur not auch mehr.

PHP

"Land_ClutterCutter_large_F"
"Land_ClutterCutter_medium_F"
"Land_ClutterCutter_small_F"

alternativ einen Hanger spawnen und ihn löschen.

Maaxxs · 9. Mai 2016

@Raven ich glaube Gras wird mit nearestObjects nicht gefunden, oder ?
und hat Gras überhaupt nen class name? ich hab das schon mal mit nearest Objects probiert, funktioniert auch gut mit Bäumen usw. aber Gras bleibt.

@Creedcoder dann wärs wohl fast sinnvoller ein paar große Hangars zu spawnen, da die "Base" ziemlich groß ist. (Flugfeld auf Chernarus) nur der Hangar dürfte dann mit keinen anderen Objekten kollidieren...
wie könnte ich denn ein Scipt schreiben, dass in einem bestimmten Radius oder bis zu bestimmten Punkten (-> Viereck) da lauter große ClutterCutter setzt?

James · 9. Mai 2016

Hallo Maaxxs,

das Problem mit Kollision kannst du umgehen, indem du das Objekt zuerst irgendwo außerhalb spawns [0,0,0] und anschließend die Physik mittels enableSimulation false ausschaltest, dann kannst du es auch in andere Objekte verschieben, ohne das es zu Explosionen kommt. Allerdings wird dann sicherlich nicht mehr das Grasplätten gehen, da das wohl nur beim Spawnen passiert. Wie es sich mit den Rasenmähern verhält, wäre dann noch zu testen, aber die kann man ja auch problemlos direkt an die entsprechende Stelle spawnen, auch wenn dort ein Objekt steht.

Ein Skript könnte so aussehen, dass du einen rechteckigen Trigger erstellst und dann folgendes Skript aufrufst, wobei du den Trigger als Objekt mit übergibst, wodurch wir die Maße der Fläche erhalten:

C

// cutter.sqf
_trg = _this select 0;
_area = triggerArea _trg;
_a = _area select 0; // Hälfte der Breite in x
_b = _area select 1; // Hälfte der Breite in y
_pos = position _trg;
// untere linke Ecke von trigger area
_startPos = [
(_pos select 0) - _a,
(_pos select 1) - _b,// Richtung hängt von Karte ab!
_pos select 2
];
_width = 10; // Größe des Rasenmäher (groß)
// Höhe: z.B. 100m / 10m = 10 Rasenmäher in x
for "_i" from 0 to (round(2 * _a / _width) - 1) do {
// Breite: z.B. 100m / 10m = 10 Rasenmäher in y
for "_j" from 0 to (round(2 * _b / _width) - 1) do {
_spawnPos = [
(_startPos select 0) + _width / 2 + _j * _width,
(_startpos select 1) + _width / 2 + _i * _width,
0
];
createVehicle ["Land_ClutterCutter_large_F", _spawnPos, [], 0, "CAN_COLLIDE"];
};
};

Alles anzeigen

Einfach einen Trigger erstellen, Bedingung auf true oder sonst wie gewünscht stellen, gewünsche Maße einstellen und anschließend bei Aktivierung [thistrigger] execVM "cutter.sqf" eingeben. Skript kann man immer optimieren, aber ich habe es jetzt so geschrieben, das jeder Schritt wirklich nachvollziehbar und offensichtlich ist.

Maaxxs · 9. Mai 2016

Vielen Dank, funktioniert echt gut. Musste die _width vom Rasemäher etwas runterstellen, damit das Gras auch restlos entfernt wird.
werde da noch bisschen dran rumschrauben

Maaxxs · 19. Mai 2016

Ich habe mir hier noch ein paar Gedanken gemacht. Ich wollte, dass die Fläche, die von Gras befreit werden soll nicht unbedingt parallel zur x- bzw y- Achse ist, also auch schräg sein kann.
Habe das mit Vektoren gelöst

Code

_obj1 = _this select 0;
_obj2 = _this select 1; //die ersten 2 Objekte stellen die Länge dar
_obj3 = _this select 2; //3. Objekt für die Richtung und Höhe der Fläche
_startPos = getPosAtl _obj1;
_vec1 = (getPosAtl _obj2) vectorDiff _startPos;
_vec2 = (getPosAtl _obj3) vectorDiff _startPos;
_normVec1 = vectorNormalized _vec1;
_normVec2 = vectorNormalized _vec2;
_newAddToPos1 = _normVec1 vectorMultiply 10; // 10 ist breite
_newAddToPos2 = _normVec2 vectorMultiply 10;
_numberForX = round ((vectorMagnitude _vec1) / 10);
_numberForY = round ((vectorMagnitude _vec2) / 10);
for "_i" from 0 to _numberForX do
{
for "_j" from 0 to _numberForY do
{
_spawnPos = (_startPos vectorAdd (_newAddToPos1 vectorMultiply _i)) vectorAdd (_newAddToPos2 vectorMultiply _j);
createVehicle ["CUP_A1_ClutterCutter", _spawnPos, [], 0, "CAN_COLLIDE"];
};
};

Alles anzeigen

das ganze mit [h1,h2,h3] execVM "cutter.sqf";ausführen. h1 usw. können zB. unsichtbare Helipads sein, dann sieht man auch nix mehr davon.
Wie im Code steht, stellen die ersten zwei übergebenen Objekte die Grundlinie dar. Das dritte Objekt dann die Höhe und Richtung.

hier Flugfeld Chernarus, Blickrichtung Nord

Teilen