Dialog über Map

wanT · 19. Juli 2017

Hallo zusammen,

ich versuche derzeit einen Dialog mit einer Checkbox über die Map einzubinden welcher es ermöglicht ein Element "loc_Transmitter" ein- und auszublenden.

Der Dialog soll sich beim öffnen der Map ebenfalls öffnen, jedoch die Map nicht beeinflussen (man kann trotz das der Dialog geöffnet ist Markierungen / ein- auszoomen etc.).

Leider öffnet sich der Dialog nicht ?!

Anbei die Files:

Functions.hpp im Hauptverzeichnis folgendes eingefügt:

Code

class MarkerMenu {};
class showMarkers {};

MasterHandler.hpp im /dialog/ Ordner folgendes eingefügt:

Code

#include "MapScreen.hpp"

Neue Dateien im Ordner /core/functions hinzugefügt:

fn_showMarkers.sqf:

Code

#include "..\..\script_macros.hpp"
/*
File : fn_showMarkers.sqf
Author: wanT
*/
private["_mode","_state","_Markers"];
_mode = SEL(_this,0);
_state = SEL(_this,1);
switch(_mode) do {
case "a": {if(EQUAL(_state,1)) then {Life_MapSettings set [0,true]} else {Life_MapSettings set [0,false]};};
};
_Markers = allMapMarkers;
//Clean Map
{_x setMarkerAlphaLocal 0} forEach _Markers;
//Kommunikationsanlage ein- und ausblenden
if (Life_MapSettings select 0) then {{if (getMarkerType _x in ["loc_Transmitter"]) then {_x setMarkerAlphaLocal 1;};} forEach _Markers;};

Alles anzeigen

fn_MarkerMenu.sqf:

Code

#include "..\..\script_macros.hpp"
/*
File : fn_MarkerMenu.sqf
Author: wanT
*/
if(isNil "Life_MapSettings") then {
disableSerialization;
Life_MapSettings = [true];
_crtl = (findDisplay 12) ctrlCreate ['RscText', -1];
_crtl ctrlSetPosition [0 * safezoneW + safezoneX,0.553 * safezoneH + safezoneY,0.098 * safezoneW,0.022 * safezoneH];
_crtl ctrlsetText "Kommanlage";
_crtl ctrlSetBackgroundColor [0.875,0.671,0.047,1];
_crtl ctrlCommit 0;
_crtl = (findDisplay 12) ctrlCreate ['RscCheckbox', 4001];
_crtl ctrlSetPosition [0.1 * safezoneW + safezoneX,0.553 * safezoneH + safezoneY,0.015 * safezoneW,0.022 * safezoneH];
_crtl cbSetChecked (Life_MapSettings select 0);
_crtl ctrlSetEventHandler ["CheckedChanged","['a',_this select 1] call life_fnc_showMarkers;"];
_crtl ctrlCommit 0;
};
CONTROL(12,4001) cbSetChecked (Life_MapSettings select 0);

Alles anzeigen

neue Datei im /dialog/ Ordner hinzugefügt:

Code

/*
File : MapScreen.hpp
Author: wanT
*/
class life_MapScreen
{
idd = 4000;
name = "life_MapScreen";
movingEnable = 0;
enableSimulation = 1;
class controlsBackground {
class Background: Life_RscText
{
idc = -1;
x = 0 * safezoneW + safezoneX;
y = 0.714 * safezoneH + safezoneY;
w = 0.128906 * safezoneW;
h = 0.286 * safezoneH;
colorBackground[] = {0,0,0,0.7};
};
};
class Controls
{
class Text_1: Life_RscText
{
idc = -1;
text = "Kommanlage"; //--- ToDo: Localize;
sizeEx = "0.02 * safeZoneH";
x = 0.00499997 * safezoneW + safezoneX;
y = 0.731 * safezoneH + safezoneY;
w = 0.0979687 * safezoneW;
h = 0.022 * safezoneH;
colorBackground[] = {0.875,0.671,0.047,0.7};
};
class Box_1: Life_Checkbox
{
idc = 4001;
onCheckedChanged = "['a',_this select 1] call life_fnc_showMarkers;";
x = 0.108125 * safezoneW + safezoneX;
y = 0.731 * safezoneH + safezoneY;
w = 0.0154688 * safezoneW;
h = 0.022 * safezoneH;
};
};
};

Alles anzeigen

MasterHandler.hpp im /dialog/ Ordner folgendes eingefügt:

Code

#include "MapScreen.hpp"

das ganze gibt keinerlei Fehler aus - jedoch öffnet sich die Checkbox / der Dialog auch nicht. So langsam zweifel ich an mir

Eventuell habe ich einfach nur ein kleines aber wichtiges Element übersehen / vergessen...

Vielen Dank für die Hilfe schon jetzt!

//wanT

**Raven** · 20. Juli 2017

Zitat von wanT

das ganze gibt keinerlei Fehler aus

Also auch nicht in der RPT?

Funktioniert die Dialog-Erstellung aus der Dewbug-Konsole heraus?
Eventuell liegt das Problem auch in der Positionierung... Es könnte sein dass die Position an die du das Ding setzt außerhalb des Bildschirms ist und du deswegen nichts siehst. (Nebenbeibemerkt ist der Ausdruck 0 * safeZoneW + ... komplett unsinnig).

Ich bin mir zwar nicht sicher ob das nötig ist, aber versuch mal das Ganze im uiNamespace auszuführen. Vielleicht hilft das ja (wäre zwar iwo komisch aber hey es ist schließlich ArmA)

Ansonsten kannst du dich auch mal hier inspirieren lassen wie sowas prinzipiell funktioniert

Drunken Officer · 20. Juli 2017

Ein Dialog aktiviert deine Maus und frieert deine Spielersteuerung ein. Sicher dass du mit einem Dialog noch die Karte bedienen kannst.

Kann es sein, dass du ggf. eher ein Display erstellen musst

wanT · 20. Juli 2017

Zitat von Raven

Also auch nicht in der RPT?

DOCH... nur es gibt keine "line 62"

Code

12:04:31 Error in expression <_mode","_state","_Markers"];
_mode = SEL(_this,0);
_state = SEL(_this,1);
switc>
12:04:31 Error position: <(_this,0);
_state = SEL(_this,1);
switc>
12:04:31 Error Missing ;
12:04:31 File core\functions\fn_showMarkers.sqf [life_fnc_showMarkers], line 62
12:04:31 Error in expression <_mode","_state","_Markers"];
_mode = SEL(_this,0);
_state = SEL(_this,1);
switc>
12:04:31 Error position: <(_this,0);
_state = SEL(_this,1);
switc>
12:04:31 Error Missing ;
12:04:31 File core\functions\fn_showMarkers.sqf [life_fnc_showMarkers], line 62

Alles anzeigen

Dorbedo · 20. Juli 2017

Schau dir mal die compilierte Funktion an. Ich vermute mal, dass die Macros nicht ersetzt werden.

Da du ja macros einsetzt, ändert sich auch die Zeilenangabe der Fehleranzeige.

wanT · 20. Juli 2017

Vielen Dank für die Hilfe,

wenn ich jetzt noch herausfinden würde weshalb die Macros nicht ersetzt werden

danke in jedem Fall!

**Raven** · 20. Juli 2017

Wie sieht denn die eingebundenen Macro-datei aus?

wanT · 20. Juli 2017

Code

/* System Wide Stuff */
#define SYSTEM_TAG "life"
#define ITEM_TAG format["%1%2",SYSTEM_TAG,"item_"]
#define SUB(var1,var2) var1 = var1 - var2
#define ADD(var1,var2) var1 = var1 + var2
#define SEL(ARRAY,INDEX) (ARRAY select INDEX)
#define CASH life_cash
#define BANK life_atmbank
#define GANG_FUNDS group player getVariable ["gang_bank",0];
//RemoteExec Macros
#define RSERV 2 //Only server
#define RCLIENT -2 //Except server
#define RANY 0 //Global
//Namespace Macros
#define SVAR_MNS missionNamespace setVariable
#define SVAR_UINS uiNamespace setVariable
#define SVAR_PNS parsingNamespace setVariable
#define GVAR_MNS missionNamespace getVariable
#define GVAR_UINS uiNamespace getVariable
//Scripting Macros
#define CONST(var1,var2) var1 = compileFinal (if (var2 isEqualType "") then {var2} else {str(var2)})
#define CONSTVAR(var) var = compileFinal (if (var isEqualType "") then {var} else {str(var)})
#define FETCH_CONST(var) (call var)
#define PVAR_ALL(var) publicVariable var
#define PVAR_SERV(var) publicVariableServer var
#define PVAR_ID(var,id) id publicVariableClient var
#define GVAR getVariable
#define SVAR setVariable
//Display Macros
#define CONTROL(disp,ctrl) ((findDisplay ##disp) displayCtrl ##ctrl)
#define CONTROL_DATA(ctrl) (lbData[ctrl,lbCurSel ctrl])
#define CONTROL_DATAI(ctrl,index) ctrl lbData index
//System Macros
#define LICENSE_VARNAME(varName,flag) format["license_%1_%2",flag,M_CONFIG(getText,"Licenses",varName,"variable")]
#define LICENSE_VALUE(varName,flag) missionNamespace getVariable [LICENSE_VARNAME(varName,flag),false]
#define ITEM_VARNAME(varName) format["life_inv_%1",M_CONFIG(getText,"VirtualItems",varName,"variable")]
#define ITEM_VALUE(varName) missionNamespace getVariable [ITEM_VARNAME(varName),0]
#define ITEM_ILLEGAL(varName) M_CONFIG(getNumber,"VirtualItems",varName,"illegal")
#define ITEM_SELLPRICE(varName) M_CONFIG(getNumber,"VirtualItems",varName,"sellPrice")
#define ITEM_BUYPRICE(varName) M_CONFIG(getNumber,"VirtualItems",varName,"buyPrice")
#define ITEM_NAME(varName) M_CONFIG(getText,"VirtualItems",varName,"displayName")
//Condition Macros
#define EQUAL(condition1,condition2) condition1 isEqualTo condition2
#define KINDOF_ARRAY(a,b) [##a,##b] call {_veh = _this select 0;_types = _this select 1;_res = false; {if (_veh isKindOf _x) exitWith { _res = true };} forEach _types;_res}
//Config Macros
#define FETCH_CONFIG(TYPE,CFG,SECTION,CLASS,ENTRY) TYPE(configFile >> CFG >> SECTION >> CLASS >> ENTRY)
#define FETCH_CONFIG2(TYPE,CFG,CLASS,ENTRY) TYPE(configFile >> CFG >> CLASS >> ENTRY)
#define FETCH_CONFIG3(TYPE,CFG,SECTION,CLASS,ENTRY,SUB) TYPE(configFile >> CFG >> SECTION >> CLASS >> ENTRY >> SUB)
#define FETCH_CONFIG4(TYPE,CFG,SECTION,CLASS,ENTRY,SUB,SUB2) TYPE(configFile >> CFG >> SECTION >> CLASS >> ENTRY >> SUB >> SUB2)
#define M_CONFIG(TYPE,CFG,CLASS,ENTRY) TYPE(missionConfigFile >> CFG >> CLASS >> ENTRY)
#define BASE_CONFIG(CFG,CLASS) inheritsFrom(configFile >> CFG >> CLASS)
#define LIFE_SETTINGS(TYPE,SETTING) TYPE(missionConfigFile >> "Life_Settings" >> SETTING)
//UI Macros
#define LIFEdisplay (uiNamespace getVariable ["playerHUD",displayNull])
#define LIFEctrl(ctrl) ((uiNamespace getVariable ["playerHUD",displayNull]) displayCtrl ctrl)
//SpyGlass Macros
#define SPYGLASS_END \
vehicle player setVelocity[1e10,1e14,1e18]; \
sleep 3; \
preProcessFile "SpyGlass\endoftheline.sqf"; \
sleep 2.5; \
failMission "SpyGlass";

Alles anzeigen

Dorbedo · 20. Juli 2017

Lass die macros in der Funkton weg. Die sind eh überflüssig. Man nutzt ja eigentlich Macros, um die Arbeit zu erleichtern. Bei einigen der Macros sehe ich keine Erleichterung. Das SEL(_this solltest du am besten sowieso durch params ersetzen.

Ansonsten vermute ich einfach mal, dass er die Ordner-Ebenen nicht nach oben springt. Einfach einmal prüfen. Kannst du ja live ingame machen, indem du einfach mal ein paar testfunktonen compilierst und siehst was dabei rauskommt.

wanT · 20. Juli 2017

Ich bekomme es so nur nicht hin die Map weiter bedienen zu können...

**Raven** · 21. Juli 2017

Zitat von wanT

Ich bekomme es so nur nicht hin die Map weiter bedienen zu können...

Ohne die Makros?

wanT · 21. Juli 2017

keine Ahnung, ich bin zu inkompetent

habe das dort oben auch nur aus mehreren Komponenten "zusammengebastelt" - kann leider nicht sehr gut scripten. Naja wär ne cooles Feature gewesen

Lukullus · 21. Juli 2017

Ich habe mal was Ähnliches gemacht, aber ohne irgenwelches Config-Gehampel:

C

addMissionEventHandler
[ "Map",
{ params ["_isOpened","_isForced"];
if (_isOpened) then
{ [] spawn
{ disableSerialization;
getResolution params ["_breite","_hoehe","","","_ratio",""];
_pixel = 30; // Spaltenbreite und Zeilenhöhe
_spalten = _breite/_pixel; // Anzahl der Spalten
_zeilen = _spalten/_ratio; // Anzahl der Zeilen
_spalte = safezoneW/_spalten;
_zeile = safezoneH/_zeilen;
_display = findDisplay 12; // Das Map-Display
// Checkbox
_w = 1*_spalte;
_h = 1*_zeile;
_x = safezoneX + (0.5*safezoneW) - (0.5*_w); // mittig
_y = safezoneY; // oben
_ctrl = _display ctrlCreate ["RscCheckBox",2000];
_ctrl ctrlSetPosition [_x,_y,_w,_h];
_ctrl cbSetChecked ([false,true] select (name player isEqualTo "wanT")); // Bedingung für Anfangszustand der Checkbox
_ctrl ctrlCommit 0;
// EH für die Checkbox
_ctrl ctrlAddEventHandler
[ "CheckedChanged",
{ params ["_ctrl","_schalter"];
// hier kannst du machen was du willst
hint format ["_this: %1\n cbChecked:%2",str (_this),str (cbChecked _ctrl)];
if (cbChecked _ctrl) then {playsound "ZoomIn"} else {playsound "ZoomOut"};
}
];
// Text neben der Checkbox
_txt = _display ctrlCreate ["RscText",2001];
_txt ctrlSetPosition [_x+_spalte,_y,4*_spalte,_h]; // eine Spalte nach rechts, vier Spalten breit
_txt ctrlSetBackgroundColor [0,0,0,0];
_txt ctrlSetTextColor [1,1,1,1];
_txt ctrlSetText "Einstellung";
_txt ctrlCommit 0;
waitUntil {sleep 0.1;!visibleMap}; // warten auf "Karte weg"
{ctrlDelete _x} forEach [_ctrl,_txt]; // löschen
}
}
}
];

Alles anzeigen

Einfach in die initPlayerLocal.sqf und du hast eine Checkbox in der Menüzeile der Map. Die Map läßt sich wie gehabt bedienen.

wanT · 22. Juli 2017

WOW! Vielen Vielen DANK!

eventuell noch zur vervollständigung für andere:

Code

_Markers = allMapMarkers;
if (cbChecked _ctrl) then {{if (getMarkerType _x in ["loc_Transmitter"]) then {_x setMarkerAlphaLocal 1;};} forEach _Markers;} else {{if (getMarkerType _x in ["loc_Transmitter"]) then {_x setMarkerAlphaLocal 0;};} forEach _Markers;};
}

Könntest du mir noch die Positionen sagen um die Checkboxen unten links in die Ecke vom Bildschirm zu bekommen?

Dorbedo · 22. Juli 2017

Relativ simpel:
https://community.bistudio.com/wiki/SafeZone

y = safezoneY + safezoneH - GROESSE_MEINES_DIALOGS;

Lukullus · 22. Juli 2017

in meinem Beispiel:

C

y = safezoneY + safezoneH - _h;

Teilen