[Official] ArmA 3 Mission Enhancement

NetFusion · 16. April 2015

ArmA 3 Mission Enhancement - Script Collection

Autor: NetFusion
GitHub: https://github.com/netfusion/AME
Aktuelle Version: 0.1 (Pre-Alpha)

Der Hintergedanke des Projekts ist der, die Features eines Realismusmods in einer Scriptversion bereitzustellen, sodass auch ohne Mods ein besseres Spielerlebnis gegeben ist.
Leider sind durch BI dort einige Grenzen gesetzt, sodass einige Techniken nicht eingesetzt werden können. Gerade diese Herausforderung motiviert mich an diesem Projekt weiter zu arbeiten.
Grundsätzlich möchte ich außerdem nicht ausschließen, dass Teile von AME in Zukunft auch als Mod zur Verfügung stehen.

AME verfolgt außerdem den Grundsatz, dass zwei Interaktionsmenüs parallel überflüssig sind. Das heißt, solange das Scrollmenü nicht deaktiviert werden kann, wird es kein alternatives Menü geben. Das Interaktionsmenü soll nicht als Feature von AME gelten.

Das Projekt ist in mehrere Module aufgeteilt, sodass unnötige Module in jeder einzelnen Mission schnell entfernt bzw. hinzugefügt werden können.

Hier ein Überblick über die aktuell implementierten Features:

BuildFOB
- Auf- und abladen von "Land_Cargo20_military_green_F" und "Land_Cargo20_white_F" auf "B_Truck_01_mover_F"
- Aufbau eines FOBs aus den Containern (Logistik und Medic Version)
- Abbau des FOB zurück zum Container
Chairs
- Hinsetzen und Aufstehen von Soldaten auf verschiedenen Stühlen/Bänken
Crates
- Bestimmen von vorgefertigten Inhalten für jegliche Kisten und/oder Fahrzeuge
DragDrop
- Ziehen und Loslassen von Kisten und statischen Waffen
Environment
- Festlegen einiger Umgebungsvariablen um die Performance in größeren Events zu steigern
GarbageCollect
- Entfernen von unnötigen Gegenständen sowie toten Einheiten während des Spiels
Grenades
- Sperren der Granaten zu Beginn des Spiels um ein unabsichtliches Werfen zu verhindern
LiveFeed
- Umbau aller "SignAd_Sponsor_F" zu Monitoren auf denen einem einzelnen Gruppenführer via Helmkamera zugeschaut werden kann
Load
- Ein- und Ausladen von Kisten in Fahrzeuge
LoadOut
- Festlegen von Ausrüstung für verschiedene Klassen von Soldaten beim Spawn und Respawn
Medical
- Umfangreiches Medicsystem mit (simulierten) Bandagen, Morphin, Schmerz, Blutverlust und Bewusstlosigkeit
- verbessertes Schadensmodell am Körper
NameTag
- Anzeigen von Spielernamen im Spiel
Teleport
- Ermöglicht an einer "FlagPole_F" zum eigenen Gruppenführer zu teleportieren
TFAR
- legt Einstellungen für den Einsatz von Task Force Arrowhead Radio fest
Zeus
- Überträgt die Berechnung der KI auf den Zeus
- Macht im Editor platzierte Objekt editierbar für Zeus

Weitere Features sind in Planung jedoch steht für mich das Optimieren der vorhandenen Scripte im Vordergrund.

Ich bin selbstverständlich für jegliche Form von Hilfe bei der Weiterentwicklung dankbar, aber nicht darauf angewiesen.
Einige haben einen Teil dieser Script in der Mission Speer schon gesehen. Die Resonanz war bisher überwiegend positiv. Ein paar Kleinigkeiten lassen sich jedoch nie vermeiden.

Bei Fragen zur Integration der Scripte in eure Mission stehe ich gerne zur Verfügung.

Astavinu · 16. April 2015

top! genau das was man braucht und nicht mehr.

NetFusion · 23. April 2015

Ich habe das Repo bis zum Release der Version 0.2 privat gestellt.
Wer trotzdem Interesse an einem Zugang hat kann sich bei mir via PM melden.

**Raven** · 30. April 2015

Also das hört sich wirklich verdammt praktisch an... Und ne geile Idee is es sowieso

NetFusion · 30. April 2015

Version 0.2 wird ein Mod sein.
Allerdings wird dieser Mod nicht bei jeden Client benötigt sondern muss lediglich auf dem Server liegen.
Die Scripte werden trotzdem weiterhin hauptsächlich clientseitig laufen um Serverleistung für die KI zu reservieren.
Der Missionsbauer behält weiterhin die Kontrolle, welche Script in seiner Mission laufen.

Neben ein paar Erleichterungen für mich als Entwickler reduziert das Ganze die Missionsgröße und Updates müssen nicht in jede alte Mission hinein kopiert werden, sondern nur auf dem Server einmalig durchgeführt werden.

X39 · 13. Juni 2015

Joko hat mein interesse geweckt
ich würde jedoch erst ein mal gern den code begutachten bevor ich eine eindeutige zusage mache

NetFusion · 22. Juni 2015

Da es das Modul leider nicht in die Version 0.2 geschafft hat, veröffentliche ich hier mal zwei Scripte des LiveFeed-Moduls der Version 0.1 in leicht abgeänderter Form.

Das LiveFeed Module ermöglicht das auf "SignAd_Sponsor_F"-Schildern, die Helmkamera befreundeter Gruppenführer angezeigt werden kann. Wichtig ist, dass auf mehreren Objekten verschiedene Kameras parallel angezeigt werden können und An- und Aus- sowie Umschalten zwischen den Spielern synchronisiert wird.
Realisiert wurde das ganz mit einem PiP-Effekts und einem "draw3D"-EventHandler.

Als erstes der Code innerhalb des "draw3D"-EventHandlers:
Leider habe ich es nicht geschafft die Kopfposition bzw. die Blickrichtung eines Spielers zu Berechnen wenn er Passagier in einem geschlossenen Fahrzeug ist (Slammer).
Ansonsten deckt das Skript alle möglichen Fälle ab und ist damit soweit ich weiß das vollständigste (Helm-)Kameraskript, dass es zur Zeit für ArmA3 gibt.

Spoiler anzeigen

PHP

/*
* AME v0.1 - LiveFeed - draw3D.sqf
* Author: NetFusion
*/
_allScreens = player getVariable ['AME_LiveFeed_Screens', []]; // Alle Screens die zur Zeit aktiviert sind
{
_screen = _x;
_camera = _screen getVariable ['AME_LiveFeed_Camera', objNull]; // Die Kamera für diesen Screen
_cameraTarget = _screen getVariable ['AME_LiveFeed_CameraTarget', objNull]; // Das Hilfsobjekt auf das die Kamera zeigt
_leaningIndicator = _screen getVariable ['AME_LiveFeed_LeaningIndicator', objNull]; // Das Hilfsobjekt zum berechnen der Vor-Zurück-Neigung des Spielers
_viewablePlayer = leader (_screen getVariable ['AME_LiveFeed_ViewableGroup', group (playableUnits select 0)]); // Der Spieler der aktuell auf dem Screen angezeigt wird
_inVehicle = vehicle _viewablePlayer != _viewablePlayer; // Ist der Spieler in einem Fahrzeug?
_isDriver = _inVehicle && (driver vehicle _viewablePlayer == _viewablePlayer); // Ist der Spieler Fahrer des Fahrzeugs?
_inTurret = _inVehicle && ((count assignedVehicleRole _viewablePlayer) > 1); // Ist der Spieler in einem Turret?
// Auslesen des Config-Eintrags für den Turret
// Sammeln der Config-Einträge aller untergeordneter Turrets zum berechenen der Ausrichtung (siehe unten, wichtig z.B. bei Fahrzeugkommandanten)
_allTurretConfigs = [];
_turretConfig = if (_inTurret) then {
_turretIndex = assignedVehicleRole _viewablePlayer select 1;
_turretConfig = (configFile >> "CfgVehicles" >> typeOf (vehicle _viewablePlayer));
{
_turretConfig = (_turretConfig >> "Turrets") select _x;
_allTurretConfigs pushBack _turretConfig;
true
} count _turretIndex;
_turretConfig
} else {objNull};
_inGunTurret = _inTurret && (getText (_turretConfig >> "body") != ""); // Ist der Spieler Gunner? (wichtig z.B. für Doorgunner in Hilekoptern)
_ownGunVisible = _inTurret && (getNumber (_turretConfig >> "hideWeaponsGunner") == 0); // Ist die eigene Waffe sichtbar? (wichtig für Firing-From-Vehicles, Copilot)
// An welchen Punkte befindet sich die Kamera?
// - Nicht im Fahrzeug oder Oberluke => Auge des Spielers
// - Gunner => am MemoryPoint der GunnerOptik
// - Fahrer in einem geschlossenen Fahrzeug => am MemoryPoint der Driveroptik
// - Ansonsten (Fahrer/Pilot in einem offenen Fahrzeug, FFV oder Passagier) => Auge des Spielers
_cameraAttachPoint = if (!_inVehicle || isTurnedOut _viewablePlayer) then {"eye"} else {
if (_inGunTurret) then {
getText (_turretConfig >> "memoryPointGunnerOptics")
} else {
if (_isDriver && getNumber (configFile >> "CfgVehicles" >> typeOf (vehicle _viewablePlayer) >> "driverForceOptics") == 1) then {
getText (configFile >> "CfgVehicles" >> typeOf (vehicle _viewablePlayer) >> "memoryPointDriverOptics")
} else {
"eye"
}
}
};
// Berechnung der Augenposition (Unterschied zwischen AASL/ATL wichtig z.B. bei Flug über Wasser/Terrain) im Modelspace
_eyePos = if (surfaceIsWater [getPos _viewablePlayer select 0, getPos _viewablePlayer select 1]) then {eyePos _viewablePlayer} else {ASLToATL eyePos _viewablePlayer};
_eyeAttachPoint = (vehicle _viewablePlayer) worldToModel _eyePos;
// Berechnung der Blickrichtung im Modelspace
_eyeDirection = ((vehicle _viewablePlayer) worldToModel (_eyePos vectorAdd eyeDirection _viewablePlayer)) vectorDiff _eyeAttachPoint;
// Berechnung der Kamerarichung
// - Nicht im Fahrzeug und am Boden => Blcikrichtung modifiziert mit der Vor-Zurück-Neigung
// - Fiegend (Fallschirmsprung/Tauchen) => Blickrichtung
// - Im Fahrzeug und in keinem Turret => Blickrichtung
// - Gunner und nicht Oberluke => Richtung der Waffe
// - Im Turret und eigene Waffe sichtbar (FFV) oder Oberluke (FFV) => Richtung der eigenen Waffe
// - Im Turret un eigene Waffe nciht sichtbar (Copilot) => Blickrichtung
_aimingVector = if (!_inTurret) then {
if (!_inVehicle && isTouchingGround _viewablePlayer) then {
_leaningIndicator attachTo [_viewablePlayer, [0, 0, 0], "leaning_axis"]; // Hilfsobjekt wird an den MemoryPoint attached
_leaningAxisAttachPoint = (getPos _leaningIndicator) vectorDiff (getPos _viewablePlayer); // Der Vektor zwischen Spieler und Hilfobjekt wird gemessen
_frontLeaningVector = vectorNormalized (_eyeAttachPoint vectorDiff _leaningAxisAttachPoint) vectorCrossProduct [1, 1, 0]; // Relevant ist nur die Vor-Zurück-Neigung
_sideLeaningVector = vectorNormalized (_eyeAttachPoint vectorDiff _leaningAxisAttachPoint) vectorCrossProduct [0, 0, 1]; // Seitliche Neigung kann auch berechnet werden, ist aber nicht weiter relevant
// Je nach Haltung variiert muss der Winkel anders berechnet werden
_frontLeaningAngle = (-1 * aCos (_frontLeaningVector select 1)) + ([31.5, 35, 70] select (['STAND', 'CROUCH', 'PRONE'] find stance _viewablePlayer));
_a = _eyeDirection vectorMultiply (cos _frontLeaningAngle);
_b = vectorNormalized _eyeDirection vectorCrossProduct [0, 0, 1];
_c = _eyeDirection vectorMultiply (sin _frontLeaningAngle);
_a vectorAdd (_b vectorCrossProduct _c)
} else {
_eyeDirection
}
} else {
if (_inGunTurret && !isTurnedOut _viewablePlayer) then {
// Um die wirkliche Ausrichtung des Turrets zu bekommen müssen die unterliegenden Ausrichtung addiert werden (Fahrzeugkommandant)
_turretBodyDir = 0;
{
_turretBodyAnimationName = getText (_x >> "animationSourceBody");
_turretBodyDir = _turretBodyDir + (deg ((vehicle _viewablePlayer) animationPhase _turretBodyAnimationName));
} count _allTurretConfigs;
_turretBodyDir = _turretBodyDir + 90;
// Die Höhe muss nochmal seperat ausgelesen werden
_turretGunAnimationName = getText (_turretConfig >> "animationSourceGun");
_turretGunDir = deg ((vehicle _viewablePlayer) animationPhase _turretGunAnimationName);
[cos _turretBodyDir, sin _turretBodyDir, sin _turretGunDir]
} else {
if (_ownGunVisible || isTurnedOut _viewablePlayer) then {
// Analog zur Berechnung der Blickrichtung im Modelspace hier mit der Waffenrichtung
((vehicle _viewablePlayer) worldToModel (_eyePos vectorAdd (_viewablePlayer weaponDirection currentWeapon _viewablePlayer))) vectorDiff _eyeAttachPoint
} else {
_eyeDirection
}
}
};
// Attachen der Kamera sowie des Hilfsobjekts für die Kamerarichtung
if (_cameraAttachPoint == "eye") then {
_camera attachTo [vehicle _viewablePlayer, _eyeAttachPoint];
_cameraTarget attachTo [vehicle _viewablePlayer, _eyeAttachPoint vectorAdd _aimingVector];
} else {
_camera attachTo [vehicle _viewablePlayer, [0, 0, 0], _cameraAttachPoint];
_cameraTarget attachTo [vehicle _viewablePlayer, _aimingVector, _cameraAttachPoint];
};
} count _allScreens;

Alles anzeigen

Um das ganze im Zusammenhang darzustellen hier noch das "initScreen.sqf"-Skript:
Es wird beim Aktivieren eines Bildschirms ausgeführt und initialisiert die Kamera inklusive des PiP-Effekts

Spoiler anzeigen

PHP

/*
* AME v0.1 - LiveFeed - initScreen.sqf
* Author: NetFusion
*/
_screen = _this;
// Erzeugen der Hilfsobjekte
_cameraTarget = "Sign_Sphere10cm_F" createVehicleLocal ((eyePos player) vectorAdd (eyeDirection player));
_leaningIndicator = "Sign_Sphere10cm_F" createVehicleLocal (getPos player);
// Verstekcen der Hilfsobjekte (auskommentieren zu Testzwecken)
hideObject _cameraTarget;
hideObject _leaningIndicator;
// Erzeugen der Kamera (erstmal am player)
_camera = "camera" camCreate eyePos player;
_camera camSetFov 0.6;
_camera camSetTarget _cameraTarget;
_camera camCommit 2;
// Erzeugen des PiP-Effekts
(netId _screen) setPiPEffect [3, 1, 0.8, 1, 0.1, [0.3, 0.3, 0.3, -0.1], [1.0, 0.0, 1.0, 1.0], [0, 0, 0, 0]];
_camera cameraEffect ['INTERNAL', 'BACK', netId _screen];
// Das Kamerabild kommt nun auf den Bildschirm (als ID wird die netId des Bildschirm genommen, da diese für jeden Bildschirm eindeutig sein muss)
_screen setObjectTexture [0, format ['#(argb,256,256,1)r2t(%1,1.0)', netId _screen]];
// Der Screen bekommt die Variablen mit setVariable mit (alternativ könnte man sie in einem Array auf das "AME_LiveFeed_Screens"-Array legen)
_screen setVariable ['AME_LiveFeed_Camera', _camera];
_screen setVariable ['AME_LiveFeed_CameraTarget', _cameraTarget];
_screen setVariable ['AME_LiveFeed_LeaningIndicator', _leaningIndicator];
// Der Screen ist aktiv und muss daher in das Array rein
_allScreens = player getVariable ['AME_LiveFeed_Screens', []];
_allScreens pushBack _screen;
player setVariable ['AME_LiveFeed_Screens', _allScreens];
// Hier wird gewartet bis der Bildschirm wieder deaktiviert wird
waitUntil {!(_screen getVariable ['AME_LiveFeed_Running', false])};
// Dann wird das Kamerabild entfernt
_screen setObjectTexture [0, ''];
// Der Screen in wieder inaktiv
_allScreens = player getVariable "AME_LiveFeed_Screens";
_allScreens = _allScreens - [_screen];
player setVariable ['AME_LiveFeed_Screens', _allScreens];
// Und die Hilfobjekte können gelöscht werden
deleteVehicle _leaningIndicator;
deleteVehicle _cameraTarget;

Alles anzeigen

Abschließen ist noch zu sagen das die beiden Skripte vollständig clientseitig laufen und dadurch keine Last auf dem Server entsteht.
Ihr könnt die Methoden gerne in euren Skripten/Mods nutzen, dafür aber bitte zumindest den Danke-Button unten links drücken
Ansonsten hab ich das ganze mal etwas kommentiert, damit vielleicht auch noch jemand etwas über SQF daraus lernen kann.

NetFusion · 3. Juli 2015

Die erste Phase der Entwicklung der Version 0.2 ist nun abgeschlossen. Alle Features sind implementiert.
Nun wird nochmal der gesamte Code überprüft und optimiert. Gleichzeitig beginnt die erste Testphase in der Bugs und Verbesserungsvorschläge gesammelt werden.
Abschließend findet dann ein finales Bugfixen statt, welches schließlich mit dem Release endet.

Wenn ihr beim Pre-Alpha testen dabei sein wollt um eure Ideen in das Projekt einfließen zu lassen, könnt ihr euch bei mir per PM melden.

**Montie** · 14. Mai 2016

Hm, geht bei diesem Projekt noch was?

**Katho** · 14. Mai 2016

wir nutzen AME zur zeit als Grundlage unserer Coopetition. Ich denke es wurde auch noch ein bisschen dran geschraubt aber net bzw. joko wissen da mehr.

Fabi · 14. Mai 2016

Naja ganz oben im Thread ist ein GitHub Link. Unter Commits kann man sich die letzten Änderungen anschauen.
Letzte Änderung vor 4 Tagen

**Montie** · 14. Mai 2016

Wer lesen kann ist klar im Vorteil

Danke für die Info

NetFusion · 25. Oktober 2016

Für alle die es noch interessiert ein kleines Statusupdate zum Projekt:

Das Projekt kam bisher in Teilen bei den Coopetitions zum Einsatz. Die gesammelten Erfahrungen waren überwiegend positiv, sodass aktuell an einem neuen Projekt gearbeitet wird, welches langfristig AME ablösen soll. Das neue Projekt ist etwas umfangreicher und wird von einem mehrköpfigen Team entwickelt.
Damit ist die Entwicklung an AME auch offiziell eingestellt und es werden keine neuen Updates kommen.

Wann das neue Projekt fertig ist steht noch nicht fest, wird aber, wenn es soweit ist, bekanntgegeben.