Fahrzeug spawnt doppelt auf einen Dedicated Server

SnakeDog · 4. September 2016

Tach zusammen,

ich habe ein Problem. Ich möchte in einen Skript ein Fahrzeug spawnen lassen. Mein Problem ist, dass das Fahrzeug auf meinem Testserver zwei mal erstellt wird. Wenn ich die Mission im Editor lade, dann wird nur ein Fahrzeug gespawnt.
Hier ist der Code Snippet, mit welchem das Fahrzeug gespawnt werden soll:

Code

_eng = createVehicle ["C_Truck_02_covered_F",[(getMarkerpos "vehiclespawn" select 0), getMarkerpos "vehiclespawn" select 1,0],[], 0, "NONE"];
_eng setFuel 1;
_eng allowDammage false;

Hat jemand eine Idee, warum auf den Server zwei Fahrzeuge erstellt werden.

Vielen Dank für die Unterstützung.

Pat-O · 4. September 2016

https://community.bistudio.com/wiki/createVehicle
Das Skript darf afaik nur von einem Rechner ausgeführt werden!
Evtl. macht das bei dir grade eben dein Rechner und der Server?

Fabi · 4. September 2016

if{!isServer} exitWith {};
Führt nur auf dem Server aus, somit nur genau ein mal.
Einfach vor deinem Code einsetzen.

**jokoho482** · 4. September 2016

Zitat von Fabi

if{!isServer} exitWith {};
Führt nur auf dem Server aus, somit nur genau ein mal.
Einfach vor deinem Code einsetzen.

achtung fabi das ist eine "gefährliche" aussage. denn wenn man z.b. der code NUR auf dem client ausgeführt wird dann passiert garnichts. denn dieser code führt den code nicht auf dem server aus sondern beendet nur die function wenn der aktuelle client nicht der server ist.

Fabi · 4. September 2016

Zitat von jokoho482

achtung fabi das ist eine "gefährliche" aussage. denn wenn man z.b. der code NUR auf dem client ausgeführt wird dann passiert garnichts. denn dieser code führt den code nicht auf dem server aus sondern beendet nur die function wenn der aktuelle client nicht der server ist.

gewagt ja, aber gefährlich?
Ich bezweifle das er den code auf mehreren clienten ausführt und nicht auf dem Server.

Belbo · 4. September 2016

Zitat von Fabi

gewagt ja, aber gefährlich?Ich bezweifle das er den code auf mehreren clienten ausführt und nicht auf dem Server.

In der init.sqf ausgeführt würde exitWith aussagen, dass aller Code danach nur noch auf dem Server ausgeführt wird. Ein einfaches
if (isServer) then {
//hier kommt der code für den server hin
};
ist da wesentlich unproblematischer.

Drunken Officer · 5. September 2016

Die Frage ist, wie und wo er es erstellt.
Trigger oder Init.sqf

Dann können wir weiter reden.

SnakeDog · 5. September 2016

Tach zusammen,

vielen Dank für die rege Teilnahme.
Ich habe meinen Anliegen leider nicht ganz verständlich vorgetragen, sorry dafür. Also der Vehicle Spawn ist nur ein Teil vom Code. Nach dem das Fahrzeug gespawnt ist, sollte der Rest des Codes noch ausgeführt werden.
mit if{!isServer} exitWith {}; hat das leider nicht geklappt.
Mit

Code

if (isServer) then {
_eng = createVehicle ["C_Truck_02_covered_F",[(getMarkerpos "vehiclespawn" select 0), getMarkerpos "vehiclespawn" select 1,0],[], 0, "NONE"];
_eng setFuel 1;
_eng allowDammage true;
};

wird ein Fahrzeug gespawnt und der Rest des Codes ordnungsgemäß ausgeführt.

Vielen Dank für die Unterstützung.

SnakeDog · 5. September 2016

Moin,

tja, dass ganze klappt nicht ganz wie gewünscht. Der Code wird aus einen Dialog heraus gestartet:

Code

action = "closeDialog 0;[[[],'snakedog\SupportOperations\MedicationDelivery.sqf'],'BIS_fnc_execVM',true] call BIS_fnc_MP;";

Hier ist der ganze Code in dem auch das Fahrzeug erstellt werden soll:

Code

// WAIT FOR PLAYER SYNCHRONIZATION
[] execVM "PWNR\Setup\JIP\waitForJIP.sqf";
_myHint ="Requesting Support Operation";
GlobalHint = _myHint;
publicVariable "GlobalHint";
hintsilent parseText _myHint;
sleep 10;
_markerArray = ["meddelivery","meddelivery_1","meddelivery_2","meddelivery_3"]; //Create marker with the names in the array in the 2D editor
_rnd = floor (random (count(_markerArray)));
_mrkSpawnSite = getMarkerPos (_markerArray select _rnd);
hint "Support Operations updated";
// Creating the marker
_markerSO = createMarker ["meddelivery", _mrkSpawnSite];
_markerSO setMarkerType "hd_objective";
_markerSO setMarkerSize [1,1];
_markerSO setMarkerColor "ColorRed";
// Creating Task
[West,"Task_3",["Wir müssen an die Bevölkerung dringend benötigte Medikamente liefern. Wenn Sie an den Bestimmungsort angekommen sind, dann warten Sie so lange die Medikamente abgeladen werden.","Lieferung von Medikamenten","Lieferung von Medikamenten"],"meddelivery",False] call BIS_fnc_taskCreate;
["Task_3","Created"] call BIS_fnc_taskSetState;
// Creating delivary vehicle
if (isServer) then {
_eng = createVehicle ["C_Truck_02_covered_F",[(getMarkerpos "vehiclespawn" select 0), getMarkerpos "vehiclespawn" select 1,0],[], 0, "NONE"];
_eng setFuel 1;
_eng allowDammage true;
};
// Creating Group to Defend the position
_grp1def = [getMarkerPos _markerSO, East, (configfile >> "CfgGroups" >> "East" >> "sub_faction_me_ins" >> "Infantry" >> "sub_group_ins_me_fireteam")] call BIS_fnc_spawnGroup;
nul = [_grp1def,getMarkerPos _markerSO, 100] call BIS_fnc_taskPatrol;
_grp2def = [getMarkerPos _markerSO, East, (configfile >> "CfgGroups" >> "East" >> "sub_faction_me_ins" >> "Infantry" >> "sub_group_ins_me_fireteam")] call BIS_fnc_spawnGroup;
nul = [_grp2def,getMarkerPos _markerSO, 100] call BIS_fnc_taskPatrol;
sleep 5;
_myHint ="Der Lieferung ist fertig, der Lieferwagen steht hinter unserer Truppentransporter (ein Kamaz mit abgedeckte Ladefläche)";
GlobalHint = _myHint;
publicVariable "GlobalHint";
hintsilent parseText _myHint;
// Wait for task conditions
waitUntil { _eng distance getMarkerpos _markerSO < 10 OR !alive _eng };
// If task failed
if (!alive _eng) exitWith {_null = ["Task_3","Failed"] call BIS_fnc_taskSetState; deleteMarker _markerSO; deletevehicle _eng; ["Task_3"] call BIS_fnc_deleteTask;};
// If task succeeded
_myHint ="Der Liferwagen wird entladen. Warten Sie bis der Wagen vollständig entladen wurde";
GlobalHint = _myHint;
publicVariable "GlobalHint";
hintsilent parseText _myHint;
sleep 60;
_myHint ="Die Medikamente wurden erfolgreich ausgeliefert. Kehren Sie in die Operationsbasis zurück";
GlobalHint = _myHint;
publicVariable "GlobalHint";
hintsilent parseText _myHint;
sleep 5;
["Task_3","Succeeded"] call BIS_fnc_taskSetState;
deleteMarker _markerSO; deletevehicle _eng;
["Task_3"] call BIS_fnc_deleteTask;

Alles anzeigen

Ab Zeile 26 bis 31 wird das Fahrzeug erstellt. Das Problem ist nun, das meine Variable _eng was eigentlich das Fahrzeug sein sollte, nicht definiert wird. Hier ist die Fehlermeldung im Spiel:
Error Nicht definierte Variable in Ausdruck: _eng

Bedeutet das, dass das Fahrzeug zwar auf dem Server erstellt wurde, aber die Variable nicht an den Clients übertragen wird? Wenn das so ist, wie kann ich das ändern. Um den Task abschließen zu können, sollten die Clients auch die Variable _eng kennen.

McDiod · 6. September 2016

Mir scheint, dass du noch sehr verwirrt bist, was Lokalität in Arma angeht. Wenn du Englisch beherrscht, lies dir mal das hier durch.

Den Truck allen Clients bekanntmachen kannst du, indem du ihn in eine nicht-lokale Variable speicherst und diese dann mit publicVariable verschickst.

Code

ENG = createVehicle ["C_Truck_02_covered_F",[(getMarkerpos "vehiclespawn" select 0), getMarkerpos "vehiclespawn" select 1,0],[], 0, "NONE"];
publicVariable "ENG";

Mit der BIS_fnc_MP führst du dein MedicationDelivery.sqf auf allen Clients + Server aus. Also jeder Befehl in dem Skript wird von jedem ein mal ausgeführt. Manche Befehle haben aber von sich aus schon globale Wirkung. Beispiel: In Zeile 13 - createMarker.
Ob ein Befehl global oder lokal wirkt und ob er globale oder lokale Parameter akzeptiert, siehst du im Biki immer oben links an dem kleinen Symbol unter der Überschrift. createMarker im Biki

Auch die Sache mit den hints solltest du dir nochmal durchlesen. Du speicherst deinen Text in _myHint und speicherst dann _myHint in GlobalHint (überflüssig - beides sind nur Variablen, keine Befehle). Dann machst du GlobalHint public. Nur das Publizieren alleine führt aber noch nicht den hint auf den anderen Clients aus. Es sieht ihn nur deswegen jeder, weil das Skript ja eh auf allen Clients ausgeführt wird.

Drunken Officer · 6. September 2016

Ein Dialog wird auf dem Clienten ausgeführt. Deinen Code brauchst du garnicht verteilen.

1. Fahrzeuge spawn und dies wird veteilt
2. SpawnGroup genaus so
3. BIS_fnc_Taskpatrol stellt den WP für die Gruppen, kann auch bei dir bleiben
4. BIS_FNC_TASKSTATE ist dafür gemacht wurden, damit es eben nicht noch zusätzlich verteilt werden muss
5. deine Hints würden lokal wirken und könnten mit remoteExec verteilt werden

Ich habe mal bissel was geändert. Bitte testen und Ergebnis posten

Code

// WAIT FOR PLAYER SYNCHRONIZATION
[] execVM "PWNR\Setup\JIP\waitForJIP.sqf";
"Requesting Support Operation" remoteExec ["hint"];
sleep 10;
_selectedMarker= ["meddelivery","meddelivery_1","meddelivery_2","meddelivery_3"] call BIS_fnc_selectRandom;
_mrkSpawnSite = getMarkerPos _selectedMarker;
"Support Operations updated" remoteExec ["hint"];
// Creating the marker
_markerSO = createMarker ["meddelivery", _mrkSpawnSite];
_markerSO setMarkerType "hd_objective";
_markerSO setMarkerSize [1,1];
_markerSO setMarkerColor "ColorRed";
// Creating Task
[West,"Task_3",["Wir müssen an die Bevölkerung dringend benötigte Medikamente liefern. Wenn Sie an den Bestimmungsort angekommen sind, dann warten Sie so lange die Medikamente abgeladen werden.","Lieferung von Medikamenten","Lieferung von Medikamenten"],"meddelivery",False] call BIS_fnc_taskCreate;
["Task_3","Created"] call BIS_fnc_taskSetState;
// Creating delivary vehicle
_eng = createVehicle ["C_Truck_02_covered_F",[(getMarkerpos "vehiclespawn" select 0), getMarkerpos "vehiclespawn" select 1,0],[], 0, "NONE"];
_eng setFuel 1;
_eng allowDammage true;
// Creating Group to Defend the position
_grp1def = [getMarkerPos _markerSO, East, (configfile >> "CfgGroups" >> "East" >> "sub_faction_me_ins" >> "Infantry" >> "sub_group_ins_me_fireteam")] call BIS_fnc_spawnGroup;
[_grp1def,getMarkerPos _markerSO, 100] call BIS_fnc_taskPatrol;
_grp2def = [getMarkerPos _markerSO, East, (configfile >> "CfgGroups" >> "East" >> "sub_faction_me_ins" >> "Infantry" >> "sub_group_ins_me_fireteam")] call BIS_fnc_spawnGroup;
[_grp2def,getMarkerPos _markerSO, 100] call BIS_fnc_taskPatrol;
sleep 5;
"Der Lieferung ist fertig, der Lieferwagen steht hinter unserer Truppentransporter (ein Kamaz mit abgedeckte Ladefläche)" remoteExec ["hint"];
// Wait for task conditions
waitUntil { _eng distance getMarkerpos _markerSO < 10 OR !alive _eng };
// If task failed
if (!alive _eng) exitWith { ["Task_3","Failed"] call BIS_fnc_taskSetState; deleteMarker _markerSO; deletevehicle _eng; ["Task_3"] call BIS_fnc_deleteTask;};
// If task succeeded
"Der Liferwagen wird entladen. Warten Sie bis der Wagen vollständig entladen wurde" remoteExec ["hint"];
sleep 60;
"Die Medikamente wurden erfolgreich ausgeliefert. Kehren Sie in die Operationsbasis zurück" remoteExec ["hint"];
sleep 5;
["Task_3","Succeeded"] call BIS_fnc_taskSetState;
deleteMarker _markerSO; deletevehicle _eng;
["Task_3"] call BIS_fnc_deleteTask;

Alles anzeigen

SnakeDog · 7. September 2016

Tach zusammen,

also KKs Blog kannte ich noch nicht, vielen Dank für den Link. Ich habe mir den Artikel ArmA Scripting Tutorials: Locality durch gelesen. Ja, dass mit den Lokalitäten in Arma war mir offensichtlich nicht richtig klar. Irgendwie haben meinen Missionen immer funktioniert, allerdings die Idee mit den Dialogen ist bei mir relativ neu, daher auch diese Komplikationen.

Den neuen Code von Drunken Officer werde ich heute Abend mal testen.

SnakeDog · 7. September 2016

Tach zusammen,

@Drunken Officer dein Code funktioniert einwandfrei, vielen Dank. Mit der publicVariable wird auch das erstellte Fahrzeug an den Clients weiter gegeben und die Clients erkennen es.

Damit hat sich meine Fragestellung soweit erledigt.
In meine zukünftige Skripte werde ich mehr auf die Arma Lokalitäten achten.

Teilen