First Person Script

Methking · 29. März 2015

Mit dem folgenden Schritten kannst du ganz einfach einstellen ob 3rd Person in deiner Mission erlaubt ist oder nicht,
ob man in einem Fahrzeug die Außenperpektive verwenden darf und oder bei welcher Geschwindigkeit! (bei Missionen mit Piloten sehr hilfreich)

1. SQF anlegen

erstelle in deinem Missionsordner eine sqf-datei und benenne sie beliebig. z.B.: "3rd.sqf"
erstelle eine "init.sqf" falls noch nicht vorhanden

öffne die Datei mit einen beliebigen Programm wie z.B.: Notepad oder den normalen Editor.

2. der code für die 3rd.sqf

Code

if (!isDedicated) then {
waitUntil {!isNull (findDisplay 46)};
if (difficultyEnabled "3rdPersonView") then
{
while {true} do {
waitUntil {cameraView == "EXTERNAL" || cameraView == "GROUP"};
if (((vehicle player) == player) && (speed (vehicle player)) >= 2) then { /// Spieler wechselt in die Ego sobald er sich in eine Richtung bewegt (Wenn der Spieler steht kann er in die Außenperspektive wechseln)
player switchCamera "INTERNAL";
};
sleep 0.1;
if (((vehicle player) != player) && (speed (vehicle player)) >= 40) then { /// Bei einer Geschwindigkeit von 40 km/h wechselt man in die Ego-perspektive (der Wert 1 (1km/h) lässt einen nur in die 3rd Person wenn das Fahrzeug nicht in Bewegung ist)
(vehicle player) switchCamera "Internal";
};
sleep 0.1;
};
};
};

Alles anzeigen

3. init.sqf

in die "init.sqf" einfügen:

Code

nul=[] execVM "3rd.sqf";

4. ausprobieren, weiterentwickeln, verbessern

greetz Methking

NetFusion · 29. März 2015

Ein super Script was ich auch schon oft (in ähnlicher Form) in Aktion gesehen habe.

Da ich kein Fan von

PHP

while {true} do { ... };

bin, empfehle ich für deine zweite Version ein rekursive Variante zu bauen.

X39 · 29. März 2015

Zitat von [C-L-F] NetFusion;1289

Ein super Script was ich auch schon oft (in ähnlicher Form) in Aktion gesehen habe.

Da ich kein Fan von

PHP

while {true} do { ... };

bin, empfehle ich für deine zweite Version ein rekursive Variante zu bauen.

leider gibt es hier keine wirklich andere lösung
actionKeys gibt sowie jemand ein ALT/SHIFT/CTRL zu der einzel taste hinzufügt nur noch müll raus womit die möglichkeit einen eventhandler hier für zu nutzen weg fällt (außer man nimmt in kauf das es nicht immer funktionieren wird)

**Raven** · 30. April 2015

Ich würde vorschlagen für die Bedingung ein

PHP

while {alive player} do {...};

zu verwenden. Das würde dann vllt im MP nützlich sein (wenn die Mission nicht mit dem Tod endet)

MFG Raven

**jokoho482** · 11. Mai 2015

PHP

// -- First Person and Thrid Person
#define enableFirstPersonOnly // Aktiviert First Person Only Deaktivieren mit //
enableVehicle3rdPerson = true; // 3rd Person in Fahrzeugen erlaubt
enable3rdPersonInBase = 300; // Entferntung von der Basis bis 3D Person Deaktiviert wird bei 0 immer First Person
//first person only
#ifdef enableFirstPersonOnly
if (difficultyEnabled "3rdPersonView") then
{
JK_FPV_EVH = addMissionEventHandler ['Draw3D', {
if ((cameraView == 'EXTERNAL') && (player distance (getMarkerPos 'respawn_west') > enable3rdPersonInBase) && (!enableVehicle3rdPerson || (vehicle player == player))) then {
vehicle player switchCamera 'INTERNAL';
};
}];
};
#endif

Alles anzeigen

Das die das was ich Aktuell in meinem Template Drinne habe und das sollte etwas Performace Sparen weil man keine While schleifen und auch keine waitUntils braucht
Diese Zeilen einfach in die Init oder InitPlayerLocal reinschreiben und die Variablen sollten alles andere erklären.
Es ist zwar etwas anders in bezug auf die wann es zurück schaltet aber sollte ja einfach anzupassen sein

Astavinu · 11. Mai 2015

haha, das kommt mir bekannt vor joko xD

**jokoho482** · 11. Mai 2015

ja ich habe es aber stark angepasst alles was While schleifen betrifft raus und die Abfrage ob es existiert in den Preprocessor getan

Drunken Officer · 15. Juni 2015

ich mache es so.
Ich lasse es initplayerlocal.sqf folgendees script laden
[1] execVM "fnc\dof_fnc_ansicht.sqf"

der Code

Code

/*
Hier kann entgegen der erlaubten Servereinstellung eine 3rd Personen unterbunden werden.
Das Script hat Clientseitig zu laufen
0 = immer erlaubt
1 = nur im Fahrzeug
2 = niemals erlaubt
*/
sleep 2;
if (!local player) exitWith {};
waitUntil {!isNull player};
waitUntil {player == player};
private ['_ansicht'];
_ansicht = _this select 0;
if (_ansicht == 0) exitWith {hint "Server allows 3rd person"};
// im Auto
while {_ansicht == 1} do
{
waitUntil {sleep 1; vehicle player == player && alive player && cameraOn == player && cameraView == "External" };
player switchCamera "internal";
};
//niemals
while {_ansicht == 2} do
{
waitUntil {sleep 1; cameraView == "External" };
player switchCamera "internal";
};

Alles anzeigen

Wobei der Rückgriff von Joko auf den Missi-EH Draw3D richtig gut ist

**jokoho482** · 15. Juni 2015

ok als erster kleiner tipp nutzte kein execVm das ding ist sowas von überholt wie nichts anders. und 2. würde ich keine whiles benutzten die können sich gerne mal aufhängen in einem asynchron umgebung also ehr nen PFEH benutzten und den dann nach bedarf hinzufügen oder entfehrnen

X39 · 15. Juni 2015

Zitat von jokoho482

ok als erster kleiner tipp nutzte kein execVm das ding ist sowas von überholt wie nichts anders. und 2. würde ich keine whiles benutzten die können sich gerne mal aufhängen in einem asynchron umgebung also ehr nen PFEH benutzten und den dann nach bedarf hinzufügen oder entfehrnen

PerFrame EventHandler (also über https://community.bistudio.com/wiki/addMissionEventHandler und draw3D) sind jedoch kritisch wenn man zu viele von ihnen verwendet
haben jedoch natürlich den vorteil das sie sofort agieren (und solange actionKeys noch immer müll zurück gibt ... unsere einzige möglichkeit um sofort zu agieren)

Drunken Officer · 15. Juni 2015

Hm ich habe jetzt mal rumprobiert und bin auf diese Lösung gestoßen:
0 = immer erlaubt
1 = nur im Fahrzeug
2 = niemals erlaubt

Eintrag in der InitPlayerlocal.sqf

Code

dof_fnc_ansichtkontrolle =
{
DOF_ansicht = _this select 0;
_id = ['WasfuereinID', 'onEachFrame',
{
if (DOF_ansichtt == 1 && vehicle player == player && alive player && cameraOn == player && cameraView == 'External') then {player switchCamera 'internal'};
if (DOF_ansicht == 2 && cameraView == 'External') then {player switchCamera 'internal'};
}] call BIS_fnc_addStackedEventHandler;
};
[1] spawn dof_fnc_ansichtkontrolle;

Alles anzeigen

X39 · 15. Juni 2015

Zitat von Drunken Officer

Hm ich habe jetzt mal rumprobiert und bin auf diese Lösung gestoßen:
0 = immer erlaubt
1 = nur im Fahrzeug
2 = niemals erlaubt

Eintrag in der InitPlayerlocal.sqf

Code

dof_fnc_ansichtkontrolle =

{

DOF_ansicht = _this select 0;

_id = ['WasfuereinID', 'onEachFrame',

{

if (DOF_ansichtt == 1 && vehicle player == player && alive player && cameraOn == player && cameraView == 'External') then {player switchCamera 'internal'};

if (DOF_ansicht == 2 && cameraView == 'External') then {player switchCamera 'internal'};

}] call BIS_fnc_addStackedEventHandler;

};

[1] spawn dof_fnc_ansichtkontrolle;

Alles anzeigen

...
http://armaworld.de/threads/37…=2307&viewfull=1#post2307
addMissionEventHandler nutzen! NICHT onEachFrame! Das dingen ist "outdated" wie sch.
(der code hinter dem link ist auch noch nicht optimal jedoch nutzt er addMissionEventHandler, optimalerweise würde noch lazyEvaluation zumindest für die erste condition angwandt)

bzgl. performance, Lieber duplikate anstatt abfragen ohne ende (if(DOF_ansicht == 1) then füge einen anderen ondraw3d EH hinzu als wenn == 1)

Drunken Officer · 16. Juni 2015

Danke, für den Tipp mit den Duplikaten

**jokoho482** · 16. Juni 2015

ich habe in meinem Template LazyEvaluation benutzt nur beim umwandeln auf die AW Variante das ausversehen rausgeworfen
weil bei mir sind gefühlte 200 weitere abfragen drinne

PHP

// -- First Person and Thrid Person
#define JK_var_enableFirstPersonOnly // Aktiviert First Person Only Deaktivieren mit //
JK_var_enableVehicle3rdPerson = true; // 3rd Person in Fahrzeugen erlaubt
JK_var_enable3rdPersonInBase = 300; // Entferntung von der Basis bis 3D Person Deaktiviert wird bei 0 immer First Person
if(!isDedicated && hasInterface) then
{
#ifdef JK_var_enableFirstPersonOnly
JK_FPV_EVH = addMissionEventHandler ['Draw3D', {
if ((cameraView == 'EXTERNAL') && (((enable3rdPersonInBase) < (player distance (getMarkerPos 'respawn_west')) && (enable3rdPersonInBase < (player distance (getMarkerPos 'respawn_east'))) && (enable3rdPersonInBase < (player distance (getMarkerPos 'respawn_guerrila'))) && (!enableVehicle3rdPerson || (vehicle player == player))))) then {
vehicle player switchCamera 'INTERNAL';
};
}];
#endif
};

Alles anzeigen

und wie währe es damit? könnte das vielleicht schneller sein

PHP

// -- First Person and Thrid Person
#define JK_var_enableFirstPersonOnly // Aktiviert First Person Only Deaktivieren mit //
JK_var_enableVehicle3rdPerson = true; // 3rd Person in Fahrzeugen erlaubt
JK_var_enable3rdPersonInBase = 300; // Entferntung von der Basis bis 3D Person Deaktiviert wird bei 0 immer First Person
if(!isDedicated && hasInterface) then
{
#ifdef JK_var_enableFirstPersonOnly
JK_FPV_EVH = addMissionEventHandler ['Draw3D', {
if (cameraView in ['INTERNAL','GUNNER']) exitWith {};
if ((JK_var_enable3rdPersonInBase) > (player distance (getMarkerPos "respawn_west"))) exitWith {};
if ((JK_var_enable3rdPersonInBase) > (player distance (getMarkerPos "respawn_east"))) exitWith {};
if ((JK_var_enable3rdPersonInBase) > (player distance (getMarkerPos "respawn_guerrila"))) exitWith {};
if (JK_var_enableVehicle3rdPerson && (vehicle player != player)) exitWith {};
vehicle player switchCamera "INTERNAL";
}];
#endif
};

Alles anzeigen

damit ist es wenigstens übersichtlicher

Allerding hat draw3d das Problem das es nur solange ausgeführt wird wie man Im Game ist und nicht im pause menü oder nicht rausgetabt ist D.H. das script ist zu umgehen wenn man raus tabt oder esc drück im selben moment wie man 3rd Person geht und es dauert trotzdem immer noch ein frame wo man in der außen perspective ist bevor man wieder in die innen perspective gewungen wird

KiloSwiss · 17. Juni 2015

jokoho482
Mit diesem Code können die Spieler nicht mehr durch ihr Visier schauen.
Du müsstest die Zeile 9 aus deinem zweiten Codeblock ändern in:

Code

[COLOR=#007700][FONT=monospace]if ([/FONT][/COLOR][COLOR=#0000BB][FONT=monospace]cameraView in[/FONT][/COLOR][COLOR=#007700][FONT=monospace] [[/FONT][/COLOR][COLOR=#DD0000][FONT=monospace]"INTERNAL","GUNNER"][/FONT][/COLOR][COLOR=#007700][FONT=monospace]) [/FONT][/COLOR][COLOR=#0000BB][FONT=monospace]exitWith [/FONT][/COLOR][COLOR=#007700][FONT=monospace]{};[/FONT][/COLOR]

Zudem ist es ratsamer dafür ein "onEachFrame" eventHandler mittels addStackedEventHandler zu verwenden, den kann man nicht mit raus tabben überlisten.

Hier ein stark simplifiziertes Beispiel, welches 3rd person view in Fahrzeugen erlaubt und für Infanteristen blockiert:

Code

['Disable3rd', 'onEachFrame', {
if (cameraView in ['INTERNAL','GUNNER']) exitWith {};
if (vehicle player != player) exitWith {};
vehicle player switchCamera "INTERNAL";
}] call BIS_fnc_addStackedEventHandler;

Hoffe ich konnte helfen.
Greez KiloSwiss

**jokoho482** · 17. Juni 2015

Zitat von X39

...
http://armaworld.de/threads/37…=2307&viewfull=1#post2307
addMissionEventHandler nutzen! NICHT onEachFrame! Das dingen ist "outdated" wie sch.
...

ich will nur noch mal X39 wieder hohlen
und ja stimmt das habe ich vergessen

**jokoho482** · 17. Juni 2015

Ich habe mal versucht Draw3D und es ist beinahe unmöglich in 3rd Person zu gehen man muss 1 FPS oder weniger haben um das zu überlisten

Psychobastard · 19. Juni 2015

Da wie ich erfahren habe, meine Kritik in diesen Bereichen neuerdings generell als Angriff verstanden wird, frage ich mal vorher: möchtest du wissen warum das Script nicht funktioniert?

Grüße

Drunken Officer · 20. Juni 2015

Ich habe durch einen Link von Rockhount folgenden Code mir zusammen gebaut. Es benötigt CBA. Vorteil ist, es rennt zwangsläufig per Frame, da man den Delay einstellen kann. Hier habe ich diesen auf 1 Sekunde gestellt.
Der Aufruf erfolgt Local (InitPlayerLocal.sqf): [1] spawn compile preprocessFileLineNumbers "fnc\dof_fnc_externeansicht.sqf";
// 1 nur im Fahrzeug
// 2 niemals

Code

if ((_this select 0) == 1) then
{
[
{
if (vehicle player == player && {cameraOn == player && {cameraView == 'External'}}) then {player switchCamera 'internal'};
},
1,
[] //
] call CBA_fnc_addPerFrameHandler;
};
if ((_this select 0) == 2) then
{
[
{
if (cameraView == 'External') then {player switchCamera 'internal'};
},
1,
[] //
] call CBA_fnc_addPerFrameHandler;
};

Alles anzeigen

KiloSwiss · 20. Juni 2015

Drunken Officer
Wozu das CBA Addon als künstliche Voraussetzung schaffen, wenn ArmA3 die benötigten Funktionen bereits von Haus aus mitbringt?
Bei ArmA2 konnte ich das zurückgreifen auf CBA verstehen, dort war es aber auch noch so dass man um onEachFrame, onPlayerConnected, etc. besser einen grossen Bogen gemacht hat, da sich diese EventHandler gegenseitig überschrieben.

In ArmA3 hat man jedoch die Möglichkeit mittels addStackedEventHandler (wurde oben bereits verlinkt), mehrere EH parallel zu erstellen und diese individuell wieder zu entfernen.
Der "Umweg" über CBA ist somit in ArmA3 nicht mehr nötig und das Überschreiben eines bereits vorhandenen EH ist auch keine Gefahr mehr (sofern man nicht bei der ID einen Fehler macht).

Zudem verstehe ich X39s Abneigung gegenüber dem onEachFrame EH nicht, es wäre durchaus interessant zu erfahren auf welchen Erfahrungen/Wissen diese beruht, man lernt ja schliesslich nie aus.

Zitat von jokoho482

Ich habe mal versucht Draw3D und es ist beinahe unmöglich in 3rd Person zu gehen man muss 1 FPS oder weniger haben um das zu überlisten

Du hast es erst jetzt getestet?
In einem vorherigen Post, schriebst Du noch:

Zitat von jokoho482

... D.H. das script ist zu umgehen wenn man raus tabt oder esc drück im selben moment wie man 3rd Person geht ...

Das hörte sich (zumindest für mich) so an, als hättest Du dies bereits ausprobiert und wärst zu eben dem beschriebenen Ergebnis gekommen.
Entschuldige wenn ich dich da falsch verstand habe.

Also gehe ich recht in der Annahme, dass es sowohl mit addStackedEventHandler + onEachFrame funktioniert, als auch mit addMissionEventHandler + Draw3D und zwar ohne dass man die Funktion überlisten kann?

First Person Script

Teilen

Tags