Städte per Script bevölkern

Fabi · 12. Juli 2016

Ich versuche aktuell Orte/Bereiche mit Zivilisten zu versehen. Dazu habe ich mir überlegt die entsprechenden Bereiche mit Markern zu whitelisten und die Anzahl der Zivilisten anhand der Markergröße zu bestimmen.
Mein aktuelles Script sieht folgendermaßen aus und wird in der "InitServer.sqf" aufgerufen.
Ich bekomme aktuell eine Fehlermeldung auf Zeile 16, dass 3 Elemente erwartet werden aber keine übergeben würden.

C

_whiteListTag ="civTown";
_markerNumber = 0;
_markerName = _whiteListTag;
while{true} do{
if(!(_markerNumber==0)) then{
_markerName = format["%1_%2",_whiteListTag,_markerNumber];
};
_markerPosition = getMarkerPos _markerName;
if ((_markerPosition isEqualTo[0,0,0])) exitWith{};
(getMarkerSize _markerName) params ["_markerSizeX","_markerSizeY"];
_aiCount = round((_markerSizeX*_markerSizeY)/100);
_markerPosition params ["_markerPositionX","_markerPositionY","_markerPositionZ"];
for "_i" from 1 to _aiCount do {
_createPosition=[(_markerPositionX-(_markerSizeX/2)+(random _markerSizeX)),(_markerPositionY-(_markerSizeY/2)+(random _markerSizeY)),0] findEmptyPosition [0,10];
if (!(_createPosition isEqualTo[0,0,0])) then{
_civ= "C_man_1" createUnit [_createPosition, (createGroup civilian)];
};
};
_markerNumber=_markerNumber+1;
}

Alles anzeigen

**Raven** · 12. Juli 2016

Also laut wiki gibt findEmptyPosition einen leeren Array und nicht [0,0,0] zurück, weswegen du vllt deine if-Abfrage ändern musst.
Dann die Standardfrage: Hast du schon geguckt, dass deine Position auch wirklich so ist, wie du denkst? Also hast du sie dir mal ausgeben lassen?

Und zu guter letzt gibt createUnit nichts zurück, sodass du das keiner Varablen zuweisen kannst (Keine Ahnung ob der Fehler daher kommt, aber n Versuch wärs wert )

MFG Raven

PhilipJFry · 12. Juli 2016

Hab das Script gerade ausprobiert und ebenfalls den beschriebenen Error bekommen. Hab es dann nochmal probiert und nun geht es!????? Habe ArmA neu gestartet und im Editor schnell alles nötige zusammen geklickt. (Player Unit, Marker(civTown), Debug Konsole aktiviert). Funktioniert auch, ohne Fehler im Log.

PhilipJFry · 12. Juli 2016

Gerade nochmal die Position des Markers verändert (Mehr Bebauen, weniger Positionierungmöglichkeiten). Dann taucht der Fehler auch wieder auf. Also wird es, wie Raven schon sagte, an findEmptyPosition liegen.

**Raven** · 12. Juli 2016

Zitat von PhilipJFry

Hab es dann nochmal probiert und nun geht es!?????

Ach ja... ArmA ist einfach eine b*tch xD

Versuch mal das Ganze so zu machen:

C

_whiteListTag ="civTown";
_markerNumber = 0;
_markerName = _whiteListTag;
_markerPosition = getMarkerPos _markerName;
while{!(_markerPosition isEqualTo [0,0,0])} do {
(getMarkerSize _markerName) params ["_markerSizeX","_markerSizeY"];
_aiCount = round((_markerSizeX*_markerSizeY)/100);
_markerPosition params ["_markerPositionX","_markerPositionY","_markerPositionZ"];
for "_i" from 1 to _aiCount do {
_createPosition=[(_markerPositionX-(_markerSizeX/2)+(random _markerSizeX)),(_markerPositionY-(_markerSizeY/2)+(random _markerSizeY)),0] findEmptyPosition [0,10];
if (count _createPosition >= 2) then{
"C_man_1" createUnit [_createPosition, (createGroup civilian)];
};
};
_markerNumber=_markerNumber+1;
_markerName = format["%1_%2",_whiteListTag,_markerNumber];
_markerPosition = getMarkerPos _markerName;
}

Alles anzeigen

Ich hab mir mal erlaubt, den while{true} raus zu nehmen, da mir das immer schmerzt, sowas im Code zu sehen
Müsste so eig genauso funktionieren (Angaben ohne Gewähr...) und ist meiner Meinung nach deutlich deskriptiver

Fabi · 12. Juli 2016

Werde es direkt mal testen.
@Raven Ich hatte ursprünglich auch ohne while {true} allerdings gefiehl mir das genauso wenig Ich vermisse eine Fußgesteuerte Schleifen

Fabi · 12. Juli 2016

So habe es etwas umgebaut
Die while{true} wird bleiben Da alle Variablen sinnvoll benannt sind sollte es sich trotzdem debuggen lassen und an der Performance dürfte es kaum einen Unterschied machen.
Da Arma scheinbar ein Gruppenlimit hat wird jetzt pro Marker nur eine Gruppe erstellt und die AI gestoppt damit diese nicht in Formation rennen
Das geänderte Script

C

_whiteListTag ="civTown";
_markerNumber = 0;
_markerName = _whiteListTag;
while{true} do{
if(!(_markerNumber==0)) then{
_markerName = format["%1_%2",_whiteListTag,_markerNumber];
};
_markerPosition = getMarkerPos _markerName;
if ((_markerPosition isEqualTo[0,0,0])) exitWith{};
(getMarkerSize _markerName) params ["_markerSizeX","_markerSizeY"];
_aiCount = round((_markerSizeX*_markerSizeY)/500);
_markerPosition params ["_markerPositionX","_markerPositionY","_markerPositionZ"];
_group =createGroup civilian;
for "_i" from 1 to _aiCount do {
_createPosition=[(_markerPositionX-(_markerSizeX/2)+(random _markerSizeX)),(_markerPositionY-(_markerSizeY/2)+(random _markerSizeY)),0] findEmptyPosition [0,10];
if (!(_createPosition isEqualTo[])) then{
"C_man_1" createUnit [_createPosition, _group, "doStop this"];
};
};
hint str _markerName;
_markerNumber=_markerNumber+1;
}

Alles anzeigen

NetFusion · 12. Juli 2016

Nutz doch diesen Befehl: https://community.bistudio.com/wiki/allMapMarkers
Dann kannst du auch deine while {true} mit count ersetzen. Außerdem funktioniert dein Skript dann auch noch, wenn zwischen civTown_1 und civTown_3 die 2 fehlt.

Sarogahtyp · 12. Juli 2016

ich will nicht weiter stören, aber es gibt schon eine script lösung für das problem. Eventuell ist es ja brauchbar, habs noch nicht getestet:
http://www.armaholic.com/page.php?id=25194

Fabi · 12. Juli 2016

@NetFusion Aber ARMA kann doch keine RegEx Wie finde ich den Tag denn dann wieder?

NetFusion · 12. Juli 2016

(_x select [0, 8]) == "civTown_"

Fabi · 12. Juli 2016

Ich hasse ARMA. Wer kommt auf so eine Idee? Vor allem muss man alles anpassen wenn sich der Tag ändert bzw. muss man es dynamischer machen

**Raven** · 12. Juli 2016

Naja also das bekommst du ja noch hin oder?

Fabi · 12. Juli 2016

ja natürlich auch wenn ich RegEx bevorzuge

Fabi · 15. Juli 2016

So wieder mal ein paar Änderungen.
-Count statt while{true}
-Fehlerbehebung Markergröße. Arma gibt nur "halbe" Kanten zurück.
-angebbare Bevölkerungsdichte
-Anpassung des Random. Marker Mitte mehr aufkommen als Rand.

C

_tag ="civtown";
_aiPerKm=500;
{
if((_x select [0, (count _tag)]) == _tag) then{
(getMarkerSize _x) params ["_markerSizeX","_markerSizeY"];
_markerPosition = getMarkerPos _x;
_markerPosition params ["_markerPositionX","_markerPositionY","_markerPositionZ"];
_aiCount = round(((_markerSizeX*_markerSizeY)/250000)*_aiPerKm);
_group =createGroup civilian;
for "_i" from 1 to _aiCount do {
_createPosition=[(_markerPositionX-(_markerSizeX)+(random [0,_markerSizeX,_markerSizeX*2])),(_markerPositionY-(_markerSizeY)+(random [0,_markerSizeY,_markerSizeY*2])),0] findEmptyPosition [0,10];
if (!(_createPosition isEqualTo[])) then{
"C_man_1" createUnit [_createPosition, _group,"doStop this"];
};
};
};
nil
}count allMapMarkers;

Alles anzeigen

Geplant
-leer stehende Fahrzeuge
-Bewegung der Zivilisten

Fabi · 18. Juli 2016

Kann da mal wer drüber schauen? Bekomme "allgemeiner Fehler in Ausdruck" auf Zeile 15.

C

fn_createRandomPosition = {
params ["_marker"];
(getMarkerPos _marker) params ["_markerPositionX","_markerPositionY","_markerPositionZ"];
_createPosition=[(_markerPositionX-(_markerSizeX)+(random [0,_markerSizeX,_markerSizeX*2])),(_markerPositionY-(_markerSizeY)+(random [0,_markerSizeY,_markerSizeY*2])),0] findEmptyPosition [0,50];
_createPosition
};
fn_moveRandomPos= {
params ["_marker","_units"];
{
if((unitReady _x) && !(isFormationLeader _x)) then{
_x doMove( _marker call fn_createRandomPosition);
};
nil
} count _units;
};
if (!isServer)exitWith{};
_tag ="civtown";
_aiPerKm=500;
{
if((_x select [0, (count _tag)]) == _tag) then{
(getMarkerSize _x) params ["_markerSizeX","_markerSizeY"];
_aiCount = round(((_markerSizeX*_markerSizeY)/250000)*_aiPerKm);
_group =createGroup civilian;
_units =[];
for "_i" from 1 to _aiCount do {
_createPosition= _x call fn_createRandomPosition;
if (!(_createPosition isEqualTo[])) then{
_unit= _group createUnit ["C_man_1",_createPosition,[],0,"NONE"];
_units pushback _unit;
};
};
[fn_moveRandomPos, 10, [_x,_units]] call CBA_fnc_addPerFrameHandler;
};
nil
}count allMapMarkers;

Alles anzeigen

Wenn ich mir _marker und _units ausgeben lasse enthält _marker das übergebene Array und _units 0.
Wenn ich jetzt Zeile 8 durch folgendes ersetze

Code

(_this select 0) params ["_marker","_units"];

enthält _marker den Marker und _untis die Einheiten. So wie es sein sollte.
Allerdings knallt mir dann der doMove in Zeile 11 mit dem Fehler "0 Elemente angegeben 3 erwartet"; Wenn ich die fn_createRandomPosition in Zeile 28 aufrufen gibt sie mir eine Position zurück. Wenn sie in Zeile 11 vom PerFrameHandler aufgerufen wird bekomme ich ein leeres Array.

**Raven** · 18. Juli 2016

Zitat von Fabi

Wenn ich mir _marker und _units ausgeben lasse enthält _marker das übergebene Array und _units 0.
Wenn ich jetzt Zeile 8 durch folgendes ersetze (...) So wie es sein sollte

Das hängt mit der Funktionasweise von dem CBA-PFH zusammen. Wenn du mal hier in Zeile 25-34 schaust, siehst du, dass die Parameter nochmals in ein "Über-Array" gesteckt werden und als zweiten Parameter noch der entsprechende Handle übergeben wird...

Zitat von Fabi

Bekomme "allgemeiner Fehler in Ausdruck" auf Zeile 15.

Da du durch die "falsche" Verwendung des params (falsch weil er was anderes gemacht hat, als du es wolltest (siehe ersten Teil)) in _units eine Zahl und keinen Array gespeichert hast, wirft dir der count einen Fehler, da er auf einfache Zahlen nicht angewendet werden kann.

Zitat von Fabi

Allerdings knallt mir dann der doMove in Zeile 11 mit dem Fehler "0 Elemente angegeben 3 erwartet";

Das bedeutet, dass deine Funktion fn_createRandomPosition ein leeres Array zurück gibt, was zu 99%-iger Sicherheit wieder mit findEmptyPosition zusammen hängt. Dh. da musst du irgendeinen SafeCheck einbauen, dass dir das Ding auf jeden Fall eine vernünftige Position zurück gibt.

Zitat von Fabi

Wenn ich die fn_createRandomPosition in Zeile 28 aufrufen gibt sie mir eine Position zurück. Wenn sie in Zeile 11 vom PerFrameHandler aufgerufen wird bekomme ich ein leeres Array.

Da würde ich einfach mal mit-loggen, um zu sehen, dass du auch wirklich den entsprechenden Marker übergeben bekommst. Ansonsten versuchs mal ohne das findEmptyPosition, um zu schauen, obs daran liegt oder an was anderem...

commy2 · 18. Juli 2016

Code: pfh_args.sqf

params ["_args", "_handle"];
_args params ["_args", "_handle"];

Ich würde empfehlen, nur einen PFH hinzuzufügen, der dann über alle Marker in einem Array läuft.

Außerdem würde ich empfehlen, dass aus diesem Marker-Array gelöschte Marker herausgenommen werden und das neue Marker hinzugefügt werden können.
Sollte das Hinzufügen von Markern nicht gewünscht sein, aber das Löschen, dann empfehle ich, dass sich der PFH selbst entfernt, wenn keine Marker mehr vorhanden sind.

Im Moment sieht der PFH nur wie ein Schleifenersatz aus.

**Raven** · 18. Juli 2016

Zitat von commy2

Im Moment sieht der PFH nur wie ein Schleifenersatz aus.

Naja... Letztendlich ist es das doch auch (also generell)

Fabi · 18. Juli 2016

Sehe ich ähnlich wie Raven.
Der große Unterschied liegt doch darin, das ich den "Thread" nicht schlafen schicke sondern den Aufruf tatsächlich nur alle x Frames ausführe. Zumindest verstehe ich den PFH mit Zeitangabe so.

Habe den Fehler in der Funktion gefunden. Ich habe auf _markerSizeX und _markerSizeY zugegriffen die in der Funktion nicht definiert wurden. Beim spawnen sind die Variablen außerhalb definiert gewesen, um den aicount zu errechnen.

Teilen