Städte per Script bevölkern

Fabi · 26. Juli 2016

Zitat von commy2

Ich verstehe nicht, warum man kritisiert, dass man alle 0.5s durch ein Array iteriert, aber dann 60 mal pro Sekunde durch "allPlayers" mit "distance2D" durchläuft.

Ich glaube das es sich hier um ein Missverständnis handelt. Die Aussage war nicht auf die Peformance bezogen sondern er darauf das bei bspw. 500ki jede Einheit "nur" alle 250sec ~ 4min überprüft wird. Da durch das Caching und die "geringe" Gruppenanzahl ki Mengen von 1000-1500 möglich wären, wäre die Abfrage zu selten.

commy2 · 26. Juli 2016

Ihr macht seltsame Dinge.

**jokoho482** · 26. Juli 2016

das "Caching" ist nur ein Maginale Performance verbesserung. d.h. bei 50 - 150 ki sollte dort auch schluss sein. irgendwie habe ich das gefühl das Fabi 0 davon verstanden hat was ich ihm versucht habe zu erläutern. und die finger von sowas lassen sollte

Fabi · 26. Juli 2016

@Joko Jain. Natürlich sind mit caching mehr KI bzw. gecachte Einheiten möglich. Da der pfh ja auch durch die gecachten einheiten laufen muss braucht er bei zu vielen Einheiten einfach zu lange bzw. müsste weitaus schneller gestellt werden als alle 0.5sec.

**Raven** · 27. Juli 2016

Zitat von Fabi

Da der pfh ja auch durch die gecachten einheiten laufen muss braucht er bei zu vielen Einheiten einfach zu lange

Und wenn du dein Caching einfach ein bisschen organisierst? Lege doch eine Multidimensionale Liste an, wo du z.B. die entsprechenden EInheiten ihrer Ortschaft zuweist und im PFH dann nur die Distanz der Spieler zu den Ortschaften überprüfst und wenn sie nahe genug dran sind, dann (und nur dann) überprüfst du die entsprechenden Einheiten in der Ortschaft...
Und wenn du tdem noch zu viele Städte hast, dann kannst du die ja auch wieder gruppieren, usw...

Creedcoder · 30. Juli 2016

Die Ideen mal ein wenig umgesetzt.

Code

_CivTown_Tag = "civtown";
_CivTown_CacheMinDistance = 1500;
_CivTown_AiPerKm = 250;
_CivTown_AiClass = [
"C_Man_casual_1_F",
"C_Man_casual_2_F",
"C_Man_casual_3_F",
"C_Man_casual_4_F",
"C_Man_casual_5_F",
"C_Man_casual_6_F"
];
_CivTown_AiType = [
"",
"_afro",
"_asia",
"_euro",
"_tanoan"
];
fn_createRandomPosition = {
params ["_marker"];
(getMarkerPos _marker) params ["_markerPositionX","_markerPositionY","_markerPositionZ"];
(getMarkerSize _marker) params ["_markerSizeX","_markerSizeY"];
_createPosition = [(_markerPositionX-(_markerSizeX)+(random [0,_markerSizeX,_markerSizeX*2])),(_markerPositionY-(_markerSizeY)+(random [0,_markerSizeY,_markerSizeY*2])),0] findEmptyPosition [0,500];
_createPosition
};
fn_moveRandomPos = {
params ["_marker", "_units"];
{
if((unitReady _x) && !(isFormationLeader _x)) then {
_x doMove( _marker call fn_createRandomPosition);
};
nil
} count _units;
};
fn_cacheUnit = {
{
_x enableSimulationGlobal false;
_x hideObjectGlobal true;
nil
} count _this;
};
fn_uncacheUnit = {
{
_x enableSimulationGlobal true;
_x hideObjectGlobal false;
nil
} count _this;
};
fn_nextFrameHandler = {
_data = (CivTown_Units select CivTown_Units_Index);
_data params ["_marker","_cachedistance", "_leader"];
_units = _data select [2, count _data];
if({(_x distance2D _leader) < _cachedistance} count allPlayers > 0) then {
if!(simulationEnabled _leader) then {
_units call fn_uncacheUnit;
[_marker, _units] call fn_moveRandomPos;
};
} else {
if(simulationEnabled _leader) then {
_units call fn_cacheUnit;
};
};
CivTown_Units_Index = CivTown_Units_Index + 1;
if(CivTown_Units_Index isEqualTo count CivTown_Units) then {
CivTown_Units_Index = 0;
};
};
CivTown_Units = [];
CivTown_Units_Index = 0;
{
if((_x select [0, (count _CivTown_Tag)]) == _CivTown_Tag) then {
(getMarkerSize _x) params ["_markerSizeX","_markerSizeY"];
_aiCount = round(((_markerSizeX * _markerSizeY) / 250000) * _CivTown_AiPerKm);
_group = createGroup civilian;
_cachedistance = switch (true) do {
case (_markerSizeX > _markerSizeY): {
(_markerSizeX + _CivTown_CacheMinDistance)
};
case (_markerSizeY > _markerSizeX): {
(_markerSizeY + _CivTown_CacheMinDistance)
};
default {
(_markerSizeX + _CivTown_CacheMinDistance)
};
};
_units_group = [_x, _cachedistance];
for "_i" from 1 to _aiCount do {
_createPosition = _x call fn_createRandomPosition;
if (!(_createPosition isEqualTo [])) then {
_class = selectRandom _CivTown_AiClass;
_type = selectRandom _CivTown_AiType;
_unit = _group createUnit [(_class + _type), _createPosition, [], 0, "NONE"];
_unit forceWalk true;
_units_group pushback _unit;
};
};
CivTown_Units pushBack _units_group;
};
nil
} count allMapMarkers;
/* für CBA
[fn_nextFrameHandler, 5] call CBA_fnc_addPerFrameHandler;
*/
//Mini PFH
PFH = [];
addMissionEventHandler ["EachFrame", {
{
_x params [["_function",{}], ["_delay",0], ["_lastExec", diag_tickTime]];
if (diag_tickTime > _lastExec) then {
_x set [2, _lastExec + _delay];
true call _function;
};
nil
} count PFH;
}];
PFH pushback [fn_nextFrameHandler, 1];

Alles anzeigen

**jokoho482** · 30. Juli 2016

hat immer noch massive problem. 1. du gehst alle Units in einem Frame Durch. was im Worse Case einen Massiven Framelag erzeugt. und 2. du chached Immer die units und ignorierst checkst nicht ab ob diese schon gecached wurden. und wenn du die 2 sachen anpassen würdest würdest du bei meiner variante rauskommen.

Creedcoder · 30. Juli 2016

Zitat von jokoho482

hat immer noch massive problem. 1. du gehst alle Units in einem Frame Durch. was im Worse Case einen Massiven Framelag erzeugt. und 2. du chached Immer die units und ignorierst checkst nicht ab ob diese schon gecached wurden. und wenn du die 2 sachen anpassen würdest würdest du bei meiner variante rauskommen.

Die Performance ist hier wesentlich besser als zu deiner Version. Es wird immer nur eine Unit pro Marker gecheckt und dann alle ge/unchached.

**jokoho482** · 30. Juli 2016

ja gut das stimmt jedoch tutst du trotzdem alles in einem Frame. was ansich unötig ist.

Teilen